Actor Superdemon
{
//Creator: NaturalxCF
//Origin: Nexus Infinity
//Sprite: SPRD
//Title: "Superdemon" 
Monster
Health 8000
Height 110
Radius 40
Mass 3000
Speed 16
PainChance 20
PainChance "Fire", 80
MinMissileChance 160
MaxTargetRange 4000
Species "Cybers"
DamageFactor 0.5
DamageFactor "Hell", 0.0
DamageFactor "Cyber10K", 0.0
DamageFactor "PDTBFG", 0.1
DamageFactor "PDTBFGTracer", 0.3
DamageFactor "PlayerDevBall", 0.05
DamageFactor "PlayerDevBall2", 0.05
DamageFactor "PlayerDevTracer", 0.05
DropItem "BossLifeEssence" 255 25
DropItem "BossArmorBonusMax" 255 1
DropItem "BossLifeEssence" 255 25
DropItem "BossArmorBonusMax" 255 1
SeeSound "cyber/sight"
ActiveSound "cyber/active"
AttackSound "None"
PainSound "cyber/pain"
DeathSound "superdemon/death"
Obituary "%o was crushed by a Superdemon." 
Tag "Superdemon"
+BOSS
+BOSSDEATH
+FLOORCLIP
+NODROPOFF
+DONTMORPH
+NORADIUSDMG
+AVOIDMELEE
+MISSILEMORE
+QUICKTORETALIATE
+DONTHARMSPECIES
States
	{
	Spawn:
		SPRD A 10 A_Look
		Loop
	See:
		SPRD A 3 A_Hoof
		SPRD ABBCC 3 A_Chase
		SPRD D 3 A_Hoof
		SPRD D 3 A_Chase
		Loop
	Missile:
		TNT1 A 0 A_Jump(128,"Comets","BigBall")
		SPRD QR 4 A_FaceTarget
		TNT1 A 0 A_CustomMissile("ArcradShot",54,0,8)
		TNT1 A 0 A_CustomMissile("ArcradShot",54,0,-8)
		SPRD S 8 A_CustomMissile("ArcradShot",54)
		SPRD QR 4 A_FaceTarget
		TNT1 A 0 A_CustomMissile("ArcradShot",54,0,8)
		TNT1 A 0 A_CustomMissile("ArcradShot",54,0,-8)
		SPRD S 8 A_CustomMissile("ArcradShot",54)
		SPRD QR 4 A_FaceTarget
		TNT1 A 0 A_CustomMissile("ArcradShot",54,0,8)
		TNT1 A 0 A_CustomMissile("ArcradShot",54,0,-8)
		SPRD S 9 A_CustomMissile("ArcradShot",54)
		Goto See
	Comets:
		SPRD QR 4 A_FaceTarget
		SPRD S 8 A_CustomMissile("ArcradimusComet2",54)
		SPRD QR 4 A_FaceTarget
		SPRD S 8 A_CustomMissile("ArcradimusComet2",54)
		SPRD EF 8 A_FaceTarget
		TNT1 A 0 A_CustomMissile("ArcradimusComet2",54,0,8)
		TNT1 A 0 A_CustomMissile("ArcradimusComet2",54,0,-8)
		SPRD G 12 A_CustomMissile("ArcradimusSeekerComet",54)
		Goto See
	BigBall:
		SPRD EEEFFF 8 A_FaceTarget
		SPRD G 20 A_CustomMissile("ArcradimusFireBall",54,0)
		Goto See	
	Pain:
		SPRD G 10 A_Pain
		TNT1 A 0 A_Jump(160,"PainMissile")
		Goto See
	PainMissile:
		TNT1 A 0 A_JumpIfTargetInLos("Missile",360,JLOSF_DEADNOJUMP|JLOSF_TARGETLOS,1700)
		Goto See
	Death:
		SPRD I 10 A_PlaySound ("superdemon/snarl", chan_5)
		SPRD J 10 Bright A_Scream
		TNT1 A 0 A_Fall
		TNT1 A 0 A_SpawnItemEx("Ultrasphere",0,0,64,random(1,8),0,2,random(0,360),0,0)
		TNT1 A 0 A_SpawnItemEx("DemonicChalice",0,0,64,random(1,8),0,2,random(0,360),0,64)
		TNT1 A 0 A_SpawnItemEx("SkullOfPower",0,0,64,random(1,8),0,2,random(0,360),0,64)
		TNT1 A 0 A_SpawnItemEx("LegendaryRune",0,0,64,random(1,8),0,2,random(0,360),0,64)
		TNT1 AA 0 A_SpawnItemEx("GibbedGenerator",frandom(-10,10),frandom(-10,10),frandom(20,60),0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAA 0 A_CustomMissile("BigRedBloodCloud",frandom(10,80),0,frandom(0,360),CMF_AIMDIRECTION,frandom(0,360))
		SPRD KKKKK 2 Bright
		TNT1 AA 0 A_SpawnItemEx("GibbedGenerator",frandom(-10,10),frandom(-10,10),frandom(20,60),0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAA 0 A_CustomMissile("BigRedBloodCloud",frandom(10,80),0,frandom(0,360),CMF_AIMDIRECTION,frandom(0,360))
		TNT1 A 0 A_CustomMissile ("SuperDemonArm", 54, -50, -50)
		SPRD LLLLL 2 Bright
		TNT1 AA 0 A_SpawnItemEx("GibbedGenerator",frandom(-10,10),frandom(-10,10),frandom(20,60),0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAA 0 A_CustomMissile("BigRedBloodCloud",frandom(10,80),0,frandom(0,360),CMF_AIMDIRECTION,frandom(0,360))
		SPRD MMMMM 2 Bright
		TNT1 AAAA 0 A_SpawnItemEx("GibbedGenerator",frandom(-10,10),frandom(-10,10),frandom(20,60),0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAAAAA 0 A_CustomMissile("BigRedBloodCloud",frandom(10,80),0,frandom(0,360),CMF_AIMDIRECTION,frandom(0,360))
		TNT1 AAAAAAAA 0 A_CustomMissile("SmokeFX3",frandom(20,80),0,frandom(0,360),CMF_AIMDIRECTION,frandom(0,360))
		SPRD N 10
		SPRD O 10 A_PlaySound("superdemon/crash")
		SPRD P 10 A_BossDeath
		SPRD P -1
		Stop
	}
}

ACTOR SuperDemonArm
{
	Radius 10
	Height 8
	Speed 1
	Damage 1
	Scale 1
	PROJECTILE
	-NOGRAVITY
	+LOWGRAVITY
	States
	{
		Spawn:
			SUPH ABC 5
			Goto Death
		Death:
			SUPH D 5
			SUPH E -1
			Stop
	}
}