ACTOR Uberchain 9941
{
//Creator: ConsulCast
//Origin: Nexus Infinity
//Sprite: UCHW/UCHF
//Title: "Uberchain"
Health 350
Radius 20
Height 56
Speed 4
PainChance 60
Mass 100
Monster
DropItem "HandGrenadeAmmo" 80 2
DropItem "MineAmmo" 45 1
DropItem "AmmoPack" 40
DropItem "AmmoPack" 40
DropItem "PortableMedkit" 159
DropItem "ArmorBooster" 186
DropItem "PortableMedkit" 159
DropItem "ArmorBooster" 186
SeeSound "UCHAIN/Sight"
ActiveSound "UCHAIN/Idle"
PainSound "UCHAIN/Pain"
Obituary "%o was riddled with holes by the Uber Chaingunner."
+FLOORCLIP
+SEEINVISIBLE
+MISSILEMORE
States
{
  Spawn:
	UCHW AABB 6 A_Look
	loop
  See:
	UCHW AAABBBCCCDDD 4 A_Chase
	loop
  Missile:
	TNT1 A 0 A_PlaySound("weapons/mgunspinstart")
	UCHF A 20 A_FaceTarget
	Goto Missile1
  Missile1:
	UCHF AA 1
	TNT1 A 0 A_PlaySound("weapons/minigunfire")
	UCHF B 1 BRIGHT A_CustomMissile("MonsterTracer",32,0, random(4, -4), CMF_OFFSETPITCH, random(2, -2))
	TNT1 A 0 A_Custombulletattack(random(-6,6),0,1,random(3,6))
	TNT1 A 0 A_SpawnItemEx("Smoke",20,10,32,1,0,1,0,0,0,0)
	UCHF B 1 BRIGHT A_CustomMissile("MonsterTracer",32,0, random(4, -4), CMF_OFFSETPITCH, random(2, -2))
	TNT1 A 0 A_Custombulletattack(random(-6,6),0,1,random(3,6))
	UCHF A 0 A_MonsterRefire(130,"CoolDown")
	Goto Missile1+1
  CoolDown:
	UCHF A 10
	TNT1 A 0 A_PlaySound("weapons/mgunspinstop")
	UCHF A 10
	TNT1 A 0 A_PlaySound("weapons/steam")
	UCHF AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 1 A_SpawnItemEx("Smoke",20,10,32,random(2,-2),random(2,-2),random(1,3),0,0,0,0)
	Goto See
  Pain:
	UCHH A 2 A_Pain
	Goto See
  Death:
	TNT1 A 0 A_Jump(130, "OtherDeath")
	TNT1 A 0 A_Playsound("UCHAIN/Death")
	UCD1 A 6 A_NoBlocking
	UCD1 BCDEF 6
	UCD1 F -1
	Stop
  OtherDeath:
	TNT1 A 0 A_Playsound("UCHAIN/Death")
	UCD3 A 6 A_NoBlocking
	UCD3 BCDEFG 6
	UCD3 G -1
	Stop
  XDeath:
	TNT1 A 0 A_XScream
	UCD2 A 6 A_NoBlocking
	UCD2 BCDEF 6
	UCD2 F -1
	Stop
  Raise:
	UCD1 F 5
	UCD1 FEDCBA 6
	Goto See
	}
}

Actor Smoke
{ 
Scale 0.20
Alpha 0.50
Speed 5
RenderStyle Add
+NOCLIP
+NOGRAVITY
+CLIENTSIDEONLY
States
{
  Spawn:
	SMOK ABCDEFGHIJKLMNOPQ 1
	Stop
    }
}