Actor SuperChaingunner
{
//Creator: Titanium
//Origin: Monsterovich (Complex-MM)
//Sprite: ZZPO
//Title: "Super Chaingunner"
Monster
Obituary "%o was drilled to bloody ribbons by a Super Chaingunner."
Health 200
GibHealth 50
Radius 20
Height 56
Mass 100
Speed 8
PainChance 50
SeeSound "chainguy/sight"
AttackSound "chainguy/attack"
PainSound "chainguy/pain"
DeathSound "chainguy/death"
ActiveSound "chainguy/active"
DropItem "HealthFlask"
DropItem "ArmorCharge"
DropItem "AmmoPack" 40 2
DropItem "HandGrenadeAmmo" 100 1
DropItem "MineAmmo" 50 1
DropItem "BulletMag" 256 10
DropItem "Clipbox"
Tag "Super Chaingunner"
+FloorClip
States
{
  Spawn:
    ZZPO AB 10 A_Look
    Loop
  See:
    ZZPO AABB 3 A_Chase
	TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
	ZZPO CCDD 3 A_Chase
	TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
    Loop
  Missile:
    ZZPO E 10 A_FaceTarget
	TNT1 A 0 A_CustomMissile("MonsterTracer",Random(30,34),0,Random(5,-5),0)
	TNT1 A 0 A_CustomMissile("MonsterTracer",Random(30,34),0,Random(5,-5),0)
	TNT1 A 0 A_SpawnItemEx("RifleCasing", 12, -6, 36, Random(-2, -6), 0, Random(-1, -3), Random(-80, -90), 128)
	TNT1 A 0 A_SpawnItemEx("RifleCasing", 12, 6, 36, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
	ZZPO EE 2 Bright A_CPosAttack
	TNT1 A 0 A_CustomMissile("MonsterTracer",Random(30,34),0,Random(5,-5),0)
	TNT1 A 0 A_CustomMissile("MonsterTracer",Random(30,34),0,Random(5,-5),0)
	TNT1 A 0 A_SpawnItemEx("RifleCasing", 12, -6, 36, Random(-2, -6), 0, Random(-1, -3), Random(-80, -90), 128)
	TNT1 A 0 A_SpawnItemEx("RifleCasing", 12, 6, 36, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
	ZZPO EE 2 Bright A_CPosAttack
    ZZPO F 1 A_CPosRefire
    Goto Missile+1
  Pain:
    ZZPO G 3
    ZZPO G 3 A_Pain
    Goto See
  Death:
    ZZPO H 5
    ZZPO I 5 A_Scream
    ZZPO J 5 A_NoBlocking
    ZZPO KLM 5
    ZZPO N -1
    Stop
  XDeath:
    ZZPO O 5 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
    ZZPO P 5 A_XScream
    ZZPO Q 5 A_NoBlocking
    ZZPO RS 5
    ZZPO T -1
    Stop
  Raise:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
    ZZPO NMLKJIH 5
    Goto See
  }
}