Actor ShadowTrooper : AssaultRifleZombie
{
//Creator: ConsulCast
//Origin: Nexus Infinity
//Sprite: SHDT
//Title: "Shadow Trooper"
Health 150
Speed 11 
Painchance 120
Obituary "%o was silently killed by a Stealth Trooper."
AttackSound "weapons/supshot"
Tag "Shadow Trooper"
States
{
  Spawn: 
	SHDT A 10 A_Look
	Loop 
  See:
	SHDT AABB 3 A_Chase 
	TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
	SHDT CCDD 3 A_Chase
	TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
	Loop
  Missile:
	SHDT A 1 A_SetTranslucent(0.75)
	SHDT A 1 A_SetTranslucent(0.55)
	SHDT A 1 A_SetTranslucent(0.35)
	SHDT A 1 A_SetTranslucent(0.15)
	TNT1 A 0 A_JumpIfCloser(750, "Close")
  Far:
    SHDT E 6 A_FaceTarget
    TNT1 A 0 A_SpawnItemEx("RifleCasing", 12, 6, 30, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
    SHDT F 2 Bright A_CustomBulletAttack(12,0,1,Random(1,5)*3)
	TNT1 A 0 A_CustomMissile("MonsterTracer",Random(30,34),0,Random(3,-3),0)
    SHDT E 2 A_FaceTarget
	TNT1 A 0 A_SpawnItemEx("RifleCasing", 12, 6, 30, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
    SHDT F 2 Bright A_CustomBulletAttack(12,0,1,Random(1,5)*3)
	TNT1 A 0 A_CustomMissile("MonsterTracer",Random(30,34),0,Random(3,-3),0)
    SHDT E 2 A_FaceTarget
    TNT1 A 0 A_SpawnItemEx("RifleCasing", 12, 6, 30, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
    SHDT F 2 Bright A_CustomBulletAttack(12,0,1,Random(1,5)*3)
	TNT1 A 0 A_CustomMissile("MonsterTracer",Random(30,34),0,Random(3,-3),0)
    SHDT E 6 A_FaceTarget		
    TNT1 A 0 A_CPosRefire
    Goto Far+1
  Close:
    SHDT E 4 A_FaceTarget
    TNT1 A 0 A_SpawnItemEx("RifleCasing", 12, 6, 30, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
    SHDT F 2 Bright A_CPosAttack
    SHDT E 3 A_FaceTarget		
    TNT1 A 0 A_CPosRefire
	Goto Close+1
  Pain:
    SHDT G 6 A_Pain
    Goto See
  Death:
    SHDT H 1 A_SetTranslucent(0.15)
	SHDT H 1 A_SetTranslucent(0.35)
	SHDT H 1 A_SetTranslucent(0.55)
	SHDT H 1 A_SetTranslucent(0.75)
	SHDT H 1 A_SetTranslucent(1)
    SHDT I 5 A_Scream
    SHDT J 5 A_Fall
    SHDT K 5 A_SpawnItem("BodyCrash",0,0,0,0)
    SHDT L -1
    Stop
  XDeath:
    SHDT M 1 A_SetTranslucent(0.15)
	SHDT M 1 A_SetTranslucent(0.35)
	SHDT M 1 A_SetTranslucent(0.55)
	SHDT M 1 A_SetTranslucent(0.75)
	SHDT M 1 A_SetTranslucent(1)
    SHDT N 3 A_XScream
    SHDT O 3 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
    SHDT P 3 A_Fall
    SHDT QRST 3
    SHDT U -1
    Stop
  Raise:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
    SHDT KJIH 5
    Goto See
	}
}