ACTOR RifleCommando
{
//Creator: Titanium
//Origin: Monsterovich (Complex-MM)
//Sprite: ACPS
//Title: "Rifle Commando"
Health 100
Radius 20
Height 56
Speed 10
Mass 100
PainChance 170
GibHealth 50
MONSTER
DropItem "Clip"
DropItem "Clip"
SeeSound "chainguy/sight"
AttackSound "weapons/assaultrifle"
PainSound "chainguy/pain"
DeathSound "chainguy/death"
ActiveSound "chainguy/active"
Obituary "%o was assaulted by a rifle commando zombie."
DropItem "HealthFlask" 35
DropItem "ArmorCharge" 35
DropItem "AmmoPack" 20
DropItem "HandGrenadeAmmo" 50 1
DropItem "MineAmmo" 25 1
DropItem "BulletMag" 256 5
Tag "Rifle Commando"
+FLOORCLIP
States 
{ 
  Spawn: 
	ACPS A 10 A_Look 
    Loop 
  See: 
    ACPS AA 4 A_Chase 
	ACPS BB 4 A_Chase 
	TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
	ACPS CC 4 A_Chase 
	ACPS DD 4 A_Chase 
	TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
    Loop 
  Missile: 
    ACPS E 10 A_FaceTarget
    TNT1 A 0 A_SpawnItemEx("RifleCasing", 12, 6, 30, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
    ACPS F 2 Bright A_CustomBulletAttack(15.4,0,1,Random(1,5)*3)
    ACPS E 1 A_CPosRefire 
    Goto Missile+1 
  Pain: 
    ACPS G 3 
    ACPS G 3 A_Pain 
    Goto See 
  Death:
    TNT1 A 0 A_Jump (125, "AltDeath")
    ACPS H 5
    ACPS I 5 A_Scream
    ACPS J 5 A_NoBlocking
    ACPS KLM 5
	TNT1 A 0 A_SpawnItem("BodyCrash",0,0,0,0)
    ACPS N -1
    Stop
  AltDeath:
    ACPS V 5 A_Scream
    ACPS W 5 
    ACPS "X" 5 A_NoBlocking
    ACPS "Y" 5 A_SpawnItem("BodyCrash",0,0,0,0)
    ACPS "Z" -1
    Stop	  
  XDeath:
    ACPS O 5 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
    ACPS P 5 A_XScream
    ACPS Q 5 A_NoBlocking
    ACPS RS 5
    ACPS T -1
    Stop
  Raise:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
    ACPS N 5
    ACPS MLKJIH 5
    Goto See
   } 
}