Actor DemonWizard
{
//Creator: "pdxbla's "VDP-MonsterRandomizer" & ElAnexo
//Origin: pdxbla's "VDP-MonsterRandomizer
//Sprite: WDEM
//Title: "Demon Wizard"
Species "Cacodemon"
Health 280
Radius 22
Height 56
Speed 12
PainChance 64
Monster
tag "Demon Wizard" 
DamageFactor 0.70
DropItem "LifeEssence" 256
DropItem "ArmorBonusMax" 256
DropItem "Backpack" 80
DropItem "HellStaff" 70
DropItem "DustMana" 256, 120
DropItem "DustMana" 128, 120
DropItem "HellionRegen", 40, 1
SeeSound "DWizard/See"
PainSound "DWizard/Pain"
DeathSound "DWizard/Death"
ActiveSound "DWizard/Active"
Obituary "%o couldn't grasp the power of the Demon Wizard."
+FLOAT
+NOGRAVITY
+MISSILEMORE
+MISSILEEVENMORE
States
{
  Spawn:
	WDEM A 10 A_Look
	Loop
  See:
	WDEM AAA 3 A_Chase
	Loop
  Missile:
	WDEM B 4 A_FaceTarget
	WDEM C 4 Bright A_FaceTarget
	TNT1 A 0 A_CustomMissile("WDemonProj",46,8,-3,0,0)
	WDEM D 3 Bright A_CustomMissile("WDemonProj2",46,-8,3,0,0)
	WDEM D 3 A_FaceTarget
	TNT1 A 0 A_CustomMissile("WDemonProj",46,8,-3,0,0)
	WDEM D 3 Bright A_CustomMissile("WDemonProj2",46,-8,3,0,0)
	WDEM D 3 A_FaceTarget
	TNT1 A 0 A_CustomMissile("WDemonProj",46,8,-3,0,0)
	WDEM D 3 Bright A_CustomMissile("WDemonProj2",46,-8,3,0,0)
	WDEM D 3 A_FaceTarget
	Goto See
  Pain:
	WDEM E 5 A_Pain
	Goto See
  Death:
	WDEM F 6 Bright A_Scream
	WDEM G 5 Bright A_NoBlocking
	WDEM H 5 Bright
	WDEM I 5 Bright
	WDEM JK 4 Bright
	WDEM L 4 A_SpawnItemEx("BishopPuff",0,0,40,0,0,0.5)
	WDEM M 4 A_QueueCorpse
	WDEM N -1
	Stop
}
}

Actor WDemonProj
{
Radius 15
Height 11
Speed 18
Damage 8
Projectile
RenderStyle Translucent
Alpha 0.8
SeeSound "WDProj/Fire"
DeathSound "WDProj/Xplode"
Decal WizardScorch
States
{
  Spawn:
	WBOL AABBCCDD 1 Bright A_Weave(3,0,1.0,0.0)
	Loop
  Death:
	WBOL EFG 4 Bright
	Stop
	}
}

Actor WDemonProj2 : WDemonProj
{
States
{
  Spawn:
	WBOL AABBCCDD 1 Bright A_Weave(-3,0,1.0,0.0)
	Loop
  Death:
	WBOL EFG 4 Bright
	Stop
	}
}