Actor Taurus : Minotaur
{
//Creator: NaturalxCF
//Origin: Nexus Infinity
//Sprite: BM00/BM01
//Title: "Battle Apprentice"
Radius 32
Height 110
Scale 1.1
Health 6500
Mass 5000
HitObituary "%o was shattered to pieces by the Taurus."
Obituary "%o was no match for the almighty Taurus."
Painchance 10
Speed 16
FloatSpeed 25
SeeSound "taurus/see"
PainSound "taurus/pain"
DeathSound "taurus/death"
ActiveSound "taurus/active"
Attacksound ""
Bloodcolor "DarkRed"
Meleerange 75
MeleeDamage 100
DamageFactor "Cyber10K", 0.0
DamageFactor "PDTBFG", 0.1
DamageFactor "PDTBFGTracer", 0.3
DamageFactor "PlayerDevBall", 0.05
DamageFactor "PlayerDevBall2", 0.05
DamageFactor "PlayerDevTracer", 0.05
DamageFactor "Hell", 0.0 
DamageFactor "Legendary", 0.75
DamageFactor "BFGSplash", 0.5
DamageFactor "PDTBFG", 0.5
DamageFactor "PDTBFGTracer", 0.5
DamageFactor "Cyber10k", 0.0
DamageFactor 0.75
Species "Cybers"
DropItem "Soulsphere"
DropItem "ExtraArmor" 1
MONSTER
Tag "Battle Apprentice"
+BOSS
+DONTRIP
+DONTMORPH
+BOSSDEATH
+NOTDMATCH
+FLOORCLIP
+NODROPOFF
-DROPOFF
+NORADIUSDMG
+NOICEDEATH
+MISSILEEVENMORE
+NOTARGET
+NOBLOCKMONST
+QUICKTORETALIATE
+NODROPOFF
+LOOKALLAROUND
+EXTREMEDEATH
+DONTHURTSPECIES
+DONTHARMSPECIES
+DONTHARMCLASS
states
{
  Spawn:
	BM00 AB 10 A_Look
	loop
  See:
	//BM00 A 0 A_ChangeFlag("QUICKTORETALIATE",1)
	BM00 A 0 A_PlaySound("taurus/hoof")
	BM00 AABB 3 A_Chase
	BM00 A 0 A_PlaySound("taurus/hoof")
	BM00 CCDD 3 A_Chase
	loop
  Melee:
	//BM01 B 0 A_ChangeFlag("QUICKTORETALIATE",0)
	BM01 B 0 A_PlaySound("taurus/meleeswing")
	BM01 B 8 A_FaceTarget
	BM01 C 5 A_FaceTarget
	BM01 D 0 A_MinotaurAtk1
	BM01 D 10 A_CustomMeleeAttack(random(20,25)*7,"taurus/meleehit","taurus/nomeleehit")
	BM01 B 0 A_JumpIfCloser(76,1)
	goto See
	BM01 E 0 A_PlaySound("taurus/meleeswing")
	BM01 E 8 A_FaceTarget
	BM01 F 5 A_FaceTarget
	BM01 D 0 A_MinotaurAtk1
	BM01 G 10 A_CustomMeleeAttack(random(20,25)*7,"taurus/meleehit","taurus/nomeleehit")
	goto See
  Missile:
	BM00 A 0 A_ChangeFlag("QUICKTORETALIATE",0)
	BM00 A 1 A_MinotaurDecide
  Hammer:
  HammerLoop:
	BM00 A 1 A_Jump(255,"MinoSpread","MinoGround","MinoRain","MinoBounce")
	goto MinoSpread
  MinoSpread:
	BM01 B 0 A_PlaySound("taurus/meleeswing")
	BM01 B 9 A_FaceTarget
	BM01 H 4 A_FaceTarget
	BM01 H 0 A_JumpIfCloser(76,9)
	BM01 I 1 A_PlaySound("taurus/spreadatk",CHAN_VOICE)
	BM01 I 1 A_CustomMissile("TaurusSpread",75,18,-12)
	BM01 I 1 A_CustomMissile("TaurusSpread",75,12,-8)
	BM01 I 1 A_CustomMissile("TaurusSpread",75,6,-4)
	BM01 I 1 A_CustomMissile("TaurusSpread",75,0,0)
	BM01 I 1 A_CustomMissile("TaurusSpread",75,-6,4)
	BM01 I 1 A_CustomMissile("TaurusSpread",75,-12,8)
	BM01 I 1 A_CustomMissile("TaurusSpread",75,-18,12)
	goto See
	BM01 I 0 A_MinotaurAtk1
	BM01 I 8 A_CustomMeleeAttack(random(25,30)*10,"taurus/meleehit","taurus/nomeleehit")
	goto See
  MinoGround:
	BM01 B 0 A_PlaySound("taurus/meleeswing")
	BM01 B 9 A_FaceTarget
	BM01 C 6 A_FaceTarget
	BM01 C 0 A_JumpIfCloser(76,3)
	BM01 D 1 A_PlaySound("taurus/groundatk",CHAN_VOICE)
	BM01 D 9 A_CustomMissile("TaurusGround")
	goto See
	BM01 D 0 A_MinotaurAtk1
	BM01 D 10 A_CustomMeleeAttack(random(25,30)*10,"taurus/meleehit","taurus/nomeleehit")
	goto See
  MinoRain:
	BM01 E 0 A_PlaySound("taurus/meleeswing")
	BM01 E 9 A_FaceTarget
	BM01 J 4 A_FaceTarget
	BM01 J 0 A_JumpIfCloser(76,9)
	BM01 K 1 A_PlaySound("taurus/spreadatk",CHAN_VOICE)
	BM01 K 2 A_CustomMissile("TaurusRain",75,-10,4)
	BM01 K 2 A_CustomMissile("TaurusRain",75,0,0)
	BM01 K 3 A_CustomMissile("TaurusRain",75,10,-4)
	goto See
	BM01 K 0 A_MinotaurAtk1
	BM01 K 8 A_CustomMeleeAttack(random(25,30)*10,"taurus/meleehit","taurus/nomeleehit")
	goto See
  MinoBounce:
	BM01 B 0 A_PlaySound("taurus/meleeswing")
	BM01 E 9 A_FaceTarget
	BM01 F 6 A_FaceTarget
	BM01 F 0 A_JumpIfCloser(76,3)
	BM01 G 1 A_PlaySound("taurus/groundatk",CHAN_VOICE)
	BM01 G 9 A_CustomMissile("TaurusBouncer",32)
	goto See
	BM01 G 0 A_MinotaurAtk1
	BM01 G 10 A_CustomMeleeAttack(random(25,30)*10,"taurus/meleehit","taurus/nomeleehit")
	goto See
  Charge:
	BM01 A 0 A_JumpIfCloser(512,2)
	BM01 A 0 A_Jump(255,"Hammer")
	BM01 A 0 A_Jump(192,"Hammer")
	BM01 A 0 A_MinotaurCharge
	BM01 A 0 A_Recoil(-1)
	BM01 A 1 A_SpawnItemEx("TaurusCharger",36,0,8,momx,momy,momz,0,SXF_ABSOLUTEMOMENTUM|SXF_NOCHECKPOSITION) //A_CustomMissile("TaurusCharger",32,0,0,CMF_AIMDIRECTION)
	BM01 A 1 A_SpawnItemEx("TaurusPuff",0,0,8,0,0,3)
	BM01 A 0 A_MinotaurCharge
	BM01 A 1 A_SpawnItemEx("TaurusCharger",36,0,8,momx,momy,momz,0,SXF_ABSOLUTEMOMENTUM|SXF_NOCHECKPOSITION) //A_CustomMissile("TaurusCharger",32,0,0,CMF_AIMDIRECTION)
	BM01 A 1 A_SpawnItemEx("TaurusPuff",0,0,8,0,0,3)
	goto Charge+3
  Pain:
	BM00 E 2
	BM00 E 8 A_Pain
	goto See
  Death:
	BM00 F 6
	TNT1 AA 0 A_SpawnItemEx("GibbedGenerator",Random(10,-10),Random(10,-10),Random(20,60),0,0,0,0,128,0)
	TNT1 AAA 0 A_CustomMissile("BigRedBloodCloud", random(10,80), 0, random(0,360), 2, random(0,360))
	BM00 G 5 Radius_Quake(8,55,0,45,0)
	BM00 H 6 A_Scream
	BM00 I 5
	TNT1 AA 0 A_SpawnItemEx("GibbedGenerator",Random(10,-10),Random(10,-10),Random(20,60),0,0,0,0,128,0)
	TNT1 AAA 0 A_CustomMissile("BigRedBloodCloud", random(10,80), 0, random(0,360), 2, random(0,360))
	BM00 J 6
	BM00 K 5 A_NoBlocking
	BM00 L 6 A_SpawnItemEx("Berserk",0,0,0,0,0,0,0,272)
	BM00 M 5 A_SpawnItemEx("Soulsphere",0,0,0,0,0,0,0,272)
	BM00 N 6
	TNT1 AA 0 A_SpawnItemEx("GibbedGenerator",Random(10,-10),Random(10,-10),Random(20,60),0,0,0,0,128,0)
	TNT1 AAA 0 A_CustomMissile("BigRedBloodCloud", random(10,80), 0, random(0,360), 2, random(0,360))
	BM00 O 5
	BM00 P 6
	BM00 Q 5
	TNT1 AA 0 A_SpawnItemEx("GibbedGenerator",Random(10,-10),Random(10,-10),Random(20,60),0,0,0,0,128,0)
	TNT1 AAA 0 A_CustomMissile("BigRedBloodCloud", random(10,80), 0, random(0,360), 2, random(0,360))
	BM00 R 6
	BM00 S 5
	BM00 TT 36
	TNT1 A 0 A_BossDeath
	BM00 T -1 A_KillMaster
	stop
	}
}

Actor TaurusSpread : FastProjectile
{
	Radius 9
	Height 6
	Speed 38
	Damage (random(3,5)*10)
	PROJECTILE
	Renderstyle add
	Deathsound "taurus/fireboom"
	states
	{
	Spawn:
		BM06 AB 6 bright
		loop
	Death:
		BM06 CDEFGH 5 bright
		stop
	}
}

Actor TaurusGround
{
	Radius 5
	Height 11
	Speed 25
	Damage (random(2,5)*10)
	PROJECTILE
	+FLOORHUGGER
	+SEEKERMISSILE
	Renderstyle add
	Seesound "taurus/firego"
	Deathsound "taurus/fireboom"
	states
	{
	Spawn:
		BM07 H 0 A_SeekerMissile(5,2)
		BM07 H 1 bright A_SpawnItemEx("TaurusGroundFire")
		loop
	Death:
		BM07 I 4 bright A_Explode(128,192,0)
		BM07 JKLM 4 bright
		stop
	}
}

Actor TaurusGroundFire
{
	Radius 5
	Height 11
	Speed 0
	Damage (random(2,5)*8)
	PROJECTILE
	+FLOORHUGGER
	Renderstyle add
	Deathsound "taurus/fireboom"
	states
	{
	Spawn:
		BM07 DC 4 bright
		BM07 BCDE 5 bright
		BM07 FGH 4 bright
		stop
	Death:
		BM07 I 4 bright A_Explode(64,128,0)
		BM07 JKLM 4 bright
		stop
	}
}

Actor TaurusRain : FastProjectile
{
	Radius 12
	Height 8
	Speed 30
	Damage (random(14,16)*5)
	PROJECTILE
	Renderstyle add
	SeeSound "taurus/rainshot"
	Deathsound "taurus/rainhit"
	states
	{
	Spawn:
		BM05 CDEF 3 bright
		loop
	Death:
		BM05 GH 5 bright
		BM05 I 4 bright
		BM05 JKL 3 bright
		TNT1 A 1 A_PlaySound("taurus/rain")
		TNT1 AAAAAAAAAAAAAAAAAAAAAAA 1 A_SpawnItemEx("TaurusRainDrop",random(-64,64),random(-64,64),0,0,0,0)
		TNT1 A 1 A_PlaySound("taurus/rain")
		TNT1 AAAAAAAAAAAAAAAAAAAAAAA 1 A_SpawnItemEx("TaurusRainDrop",random(-64,64),random(-64,64),0,0,0,0)
		TNT1 A 1 A_PlaySound("taurus/rain")
		TNT1 AAAAAAAAAAAAAAAAAAAAAAA 1 A_SpawnItemEx("TaurusRainDrop",random(-64,64),random(-64,64),0,0,0,0)
		TNT1 A 1 A_PlaySound("taurus/rain")
		TNT1 AAAAAAAAAAAAAAAAAAAAAAA 1 A_SpawnItemEx("TaurusRainDrop",random(-64,64),random(-64,64),0,0,0,0)
		TNT1 A 1 A_PlaySound("taurus/rain")
		TNT1 AAAAAAAAAAAAAAAAAAAAAAA 1 A_SpawnItemEx("TaurusRainDrop",random(-64,64),random(-64,64),0,0,0,0)
		TNT1 A 1 A_PlaySound("taurus/rain")
		TNT1 AAAAAAAAAAAAAAAAAAAAAAA 1 A_SpawnItemEx("TaurusRainDrop",random(-64,64),random(-64,64),0,0,0,0)
		stop
	}
}

Actor TaurusRainDrop
{
	Radius 3
	Height 4
	Speed 12
	Damage (random(4,6)*4)
	Gravity 12
	+MISSILE
	+BRIGHT
	+CEILINGHUGGER
    +DONTSPLASH   
    +EXPLODEONWATER
    -CANBOUNCEWATER
    -NOTELEPORT
	-TELEPORT
	Renderstyle Add
	Mass 10
	States
	{
	Spawn:
		TNT1 A 2
	Spawn2:
		BM05 M 1 bright A_JumpIf(momz >= 0,"Death")
		BM05 M 1 bright
		loop
	Death:
		BM05 NOPQR 3 bright
		stop
	}
}

Actor TaurusBouncer : MaceFX4
{
	Radius 12
	Height 17
	Speed 12
	Damage (500)
	Gravity 0.125
	PROJECTILE
	+SEEKERMISSILE
	+DONTREFLECT
	+FORCERADIUSDMG
	+EXTREMEDEATH
	-TELESTOMP
	-NOGRAVITY
	-THRUGHOST
	BounceType "Heretic"
	SeeSound ""
	Deathsound "taurus/fireboom"
	states
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIfInventory("Clip",1,2)
		TNT1 A 0 A_Jump(255,"Spawn2")
		TNT1 A 0 A_SeekerMissile(360,360)
		TNT1 A 0 A_PlaySound("taurus/hammerbounce",CHAN_VOICE)
		TNT1 A 0 A_CustomMissile("TaurusSmallBouncer",8,0,-44,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,10)
		TNT1 A 0 A_CustomMissile("TaurusSmallBouncerNS",8,0,-33,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,10)
		TNT1 A 0 A_CustomMissile("TaurusSmallBouncer",8,0,-22,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,10)
		TNT1 A 0 A_CustomMissile("TaurusSmallBouncerNS",8,0,-11,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,10)
		TNT1 A 0 A_CustomMissile("TaurusSmallBouncer",8,0,0,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,10)
		TNT1 A 0 A_CustomMissile("TaurusSmallBouncerNS",8,0,11,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,10)
		TNT1 A 0 A_CustomMissile("TaurusSmallBouncer",8,0,22,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,10)
		TNT1 A 0 A_CustomMissile("TaurusSmallBouncerNS",8,0,33,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,10)
		TNT1 A 0 A_CustomMissile("TaurusSmallBouncer",8,0,44,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,10)
	Spawn2:
		BM10 EF 8 bright A_GiveInventory("Clip",1)
		loop
	Death:
		BM02 I 3 bright A_DeathBallImpact
		BM02 J 3 bright A_ChangeFlag("NOGRAVITY",1)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,0,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,10,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,20,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,30,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,40,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,50,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,60,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,70,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,80,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,90,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,100,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,110,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,120,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,130,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,140,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,150,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,160,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,170,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,180,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,190,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,200,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,210,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,220,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,230,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,240,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,250,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,260,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,270,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,280,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,290,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,300,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,310,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,320,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,330,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncer",8,0,340,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		TNT1 A 0 A_CustomMissile("TaurusMiniBouncerNS",8,0,350,CMF_TRACKOWNER|16|CMF_AIMDIRECTION,7)
		BM02 KLMNOPQR 3 bright
		stop
	}
}

Actor TaurusSmallBouncer : MaceFX1
{
	Radius 8
	Height 6
	Speed 15
	Damage (random(15,20))
	Gravity 0.125
	PROJECTILE
	+DONTREFLECT
	-TELESTOMP
	-THRUGHOST
	-NOGRAVITY
	+EXTREMEDEATH
	BounceType "Heretic"
	SeeSound "taurus/hammersee"
	DeathSound "taurus/hammerdeath"
	states
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIfInventory("Clip",1,2)
		TNT1 A 0 A_Jump(255,"Spawn2")
		TNT1 A 0 A_PlaySound("taurus/minibounce",CHAN_VOICE)
	Spawn2:
		TNT1 A 0 A_GiveInventory("Clip",1)
		BM10 CD 4 bright A_MacePL1Check
		loop
	Death:
		BM10 G 4 bright A_MaceBallImpact
		BM10 HIJK 4 bright
		stop
	}
}

Actor TaurusSmallBouncerNS : TaurusSmallBouncer
{
	states
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIfInventory("Clip",1,2)
		TNT1 A 0 A_Jump(255,"Spawn2")
		TNT1 A 0 A_PlaySound("taurus/none",CHAN_VOICE)
	Spawn2:
		TNT1 A 0 A_GiveInventory("Clip",1)
		BM10 CD 4 bright A_MacePL1Check
		loop
	Death:
		BM10 G 4 bright A_MaceBallImpact
		BM10 HIJK 4 bright
		stop
	}
}

Actor TaurusMiniBouncer : TaurusSmallBouncer
{
	Damage (10)
	states
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIfInventory("Clip",1,2)
		TNT1 A 0 A_Jump(255,"Spawn2")
		TNT1 A 0 A_PlaySound("taurus/minibounce",CHAN_VOICE)
	Spawn2:
		TNT1 A 0 A_GiveInventory("Clip",1)
		BM10 AB 4 bright A_MacePL1Check
		loop
	Death:
		BM10 G 4 bright A_MaceBallImpact
		BM10 HIJK 4 bright
		stop
	}
}

Actor TaurusMiniBouncerNS : TaurusMiniBouncer
{
	states
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIfInventory("Clip",1,2)
		TNT1 A 0 A_Jump(255,"Spawn2")
		TNT1 A 0 A_PlaySound("taurus/none",CHAN_VOICE)
	Spawn2:
		TNT1 A 0 A_GiveInventory("Clip",1)
		BM10 AB 4 bright A_MacePL1Check
		loop
	Death:
		BM10 G 4 bright A_MaceBallImpact
		BM10 HIJK 4 bright
		stop
	}
}

Actor TaurusPuff : PhoenixPuff
{
	+CLIENTSIDEONLY
	VSpeed 1.0
	Renderstyle add
	states
	{
	Spawn:
		BM08 BCDEF 4
		stop
	}
}

Actor TaurusCharger
{
	Radius 16
	Height 32
	Damage (75)
	Speed 0 //22
	PROJECTILE
	+EXTREMEDEATH
	+FORCERADIUSDMG
	states
	{
	Spawn:
		TNT1 A 0
		TNT1 A 2
		goto Death
	XDeath:
	Crash:
		TNT1 A 0 A_PlaySound("taurus/chargehit")
	Death:
		TNT1 A 0 A_Explode(64,40,0)
		stop
	}
}