ACTOR Blink : BaronOfHell
{
//Creator: Monsterovich (Complex-MM) & Titanium
//Origin: Nexus Infinity
//Sprite: BLIN
//Title: "Blink" 
Health 1500 
GibHealth 50
Speed 10
Meleedamage 15 
BloodColor Purple
MeleeSound "baron/melee"
REACTIONTIME 8
Missiletype BlinkBall
Obituary "%o was murdered by a Blink's pink energy." 
HitObituary "The last thing %o saw was the Blink's slash." 
PainChance "SoulToxic", 20
PainChance "FatFlamer", 20
PainChance "FiendFire", 20
DropItem "LifeEssence" 100
DropItem "ArmorBonusMax" 100
Tag "\c[t6]Blink\c-"
States 
{ 
   Spawn: 
      BLIN AB 10 A_Look 
      Loop 
   See: 
      BLIN AABB 3 A_Chase
	  TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
	  BLIN CCDD 3 A_Chase
	  TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
      Loop
   SpreadAttack:
      BLIN EFG 8 A_FaceTarget  
      BLIN G 0 A_CustomMissile("BlinkBall", 32, 0) 
	  BLIN G 0 A_CustomMissile("BlinkBall", 32, 0, 10) 
	  BLIN G 0 A_CustomMissile("BlinkBall", 32, 0, -10) 
      BLIN EFG 8 A_FaceTarget 
      BLIN G 0 A_CustomMissile("BlinkBall", 32, 0) 
	  BLIN G 0 A_CustomMissile("BlinkBall", 32, 0, 10) 
	  BLIN G 0 A_CustomMissile("BlinkBall", 32, 0, -10)
	  Goto See
   RushAttack:
      BLIN EF 8 A_FaceTarget 
	  TNT1 A 0 A_Recoil(-24)
      BLIN G 8 A_MeleeAttack
      BLIN EF 8 A_FaceTarget 
	  TNT1 A 0 A_Recoil(-24)
      BLIN G 8 A_MeleeAttack
	  Goto See
   Missile:
	  BLIN E 0 A_Jump(64, "SpreadAttack")
      BLIN EF 8 A_FaceTarget 
      BLIN G 8 A_CustomMissile("BlinkBall", 32, 0) 
      BLIN F 8 A_FaceTarget 
      BLIN G 8 A_CustomMissile("BlinkBall", 32, 0) 
      BLIN F 8 A_FaceTarget 
      BLIN G 8 A_CustomMissile("BlinkBall", 32, 0) 
      Goto See 
   Melee: 
      BLIN E 0 A_Jump(128, "RushAttack")
      BLIN EF 8 A_FaceTarget
	  TNT1 A 0 A_Recoil(-10)
      BLIN G 8 A_MeleeAttack
      Goto See 
   Pain: 
      BLIN H 2 
      BLIN H 2 A_Pain 
      Goto See 
   Death: 
      BLIN I 8
      BLIN J 8 A_Scream 
      BLIN K 8 
      BLIN L 8 A_NoBlocking 
      BLIN MN 8  
	  TNT1 A 0 A_SpawnItem("BodyCrash",0,0,0,0)
	  TNT1 A 0 A_BossDeath
      BLIN O -1 
      Stop 
   XDeath:
	  NULL A 0 A_NoBlocking
	  BLXD Q 5 A_XScream
	  BLXD R 5 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,128)
	  BLXD STU 8 A_NoBlocking
	  TNT1 A 0 A_BossDeath
	  BLXD V -1
	  Stop
   Raise: 
	  TNT1 A 0
	  TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
      BLIN ONMLKJI 8 
      Goto See 
   } 
}

actor BlinkBall
{
    Radius 6
    Height 8
    Speed 25
    Damage 10
    PROJECTILE
    RENDERSTYLE ADD
    ALPHA 0.67
    SeeSound "imp/attack"
    DeathSound "imp/shotx"
    Decal BaronScorch
	+SEEKERMISSILE
    States
    {
    Spawn:
		TNT1 A 0 A_SeekerMissile(0, 2)
        BLBA A 1 Bright A_SpawnItemEx("BlinkBallTrail")
		TNT1 A 0 A_SeekerMissile(0, 2)
		BLBA B 1 Bright A_SpawnItemEx("BlinkBallTrail")
        Loop
    Death:
		TNT1 AAAAAA 0 A_CustomMissile("SmokeFX4", 0, 0, random(0,360), 2, random(0,360))
        BLBA CDE 6 Bright
        Stop
    }
}

ACTOR BlinkBallTrail : MissileTrail
{
	Scale 1
	States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
		TNT1 A 1
		BLBA AB 2 Bright A_FadeOut(0.03)
		Stop
	}
}