ACTOR PlanC : CustomInventory 32450
{
Inventory.Amount 1
Inventory.MaxAmount 1
Inventory.PickupSound "devilchest/good"
Inventory.UseSound ""
Inventory.PickupMessage "Plan C. When Plan A and Plan B fails."
Tag "Plan C"
Inventory.Icon "PILCB0"
+INVENTORY.INVBAR
+INVENTORY.NEVERRESPAWN
+COUNTITEM
+FLOORCLIP
+NOTIMEFREEZE
States
	{
 Spawn:
    PILC A 1
    Loop
 Use:
	TNT1 A 0
	TNT1 A 0 A_CheckFlag("Invulnerable","NiceTry")
	TNT1 A 1 A_SpawnItemEx("PlanCBoom",0,0,15,0,0,0,0)
	Stop
 NiceTry:
	TNT1 A 0 A_Print("Nice Try! You can't use this item while being invulnerable!")
	Fail
      }
}

ACTOR PlanCBoom
{
PROJECTILE
Height 8
Radius 13
Speed 3
Renderstyle Normal
Damage 512
+FOILINVUL
+FORCERADIUSDMG
+STRIFEDAMAGE
+EXTREMEDEATH
+NOTIMEFREEZE
+SKYEXPLODE
+DontReflect
+NOTARGET
+FULLVOLDEATH
+THRUGHOST
-ROCKETTRAIL
+ThruSpecies
+DontHurtSpecies
+DontHarmSpecies
Species "Player"
Damagetype "Explosion"
Obituary "%o tries to swallow a Plan C medicine."
States
	{
	Spawn:
		TNT1 A 0 NoDelay A_AlertMonsters
	Death:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_CustomMissile("NuclearPillExplosion",0,0,0,CMF_AIMDIRECTION|CMF_TRACKOWNER,0)
		TNT1 A 1 Bright
		Stop
	}
}

Actor NuclearPillExplosion : PlanCBoom
{
Speed 0
var int user_lcounter;
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_Die
		Goto Death
	Death:
		TNT1 A 0 Bright
		TNT1 A 1 Bright A_Explode(10000,1200,true,true,666)
		TNT1 A 1 Bright A_SpawnItemEx("PlayerNuke",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_TRANSFERPOINTERS|SXF_SETMASTER)
		TNT1 A 0 Bright A_SetUserVar("user_lcounter",0)
		TNT1 A 0 Bright A_Blast(BF_DONTWARN,225,1000,30)
		Goto NuclearFireLoop
	NuclearFireLoop:
		TNT1 A 1 Bright A_CustomMissile("NuclearPillEx",0,0,user_lcounter*20,CMF_AIMDIRECTION|CMF_TRACKOWNER)
		TNT1 A 0 Bright A_CustomMissile("NuclearPillEx2",0,0,user_lcounter*20,CMF_AIMDIRECTION|CMF_TRACKOWNER,45)
		TNT1 A 0 Bright A_CustomMissile("NuclearPillEx2",0,0,user_lcounter*20,CMF_AIMDIRECTION|CMF_TRACKOWNER,-45)
		TNT1 A 0 Bright A_CustomMissile("NuclearPillEx2",0,0,360-(user_lcounter*20),CMF_AIMDIRECTION|CMF_TRACKOWNER,45)
		TNT1 A 0 Bright A_CustomMissile("NuclearPillEx2",0,0,360-(user_lcounter*20),CMF_AIMDIRECTION|CMF_TRACKOWNER,-45)
		//TNT1 AAA 0 Bright A_SpawnItemEx("HemNuclearFlare",random(-150,150),random(-150,150),random(0,10),random(0,8),random(0,8),2,random(0,360),SXF_NOCHECKPOSITION|SXF_TRANSFERPOINTERS|SXF_SETMASTER,96)
		TNT1 A 0 Bright A_SetUserVar("user_lcounter",user_lcounter+1)
		TNT1 A 0 Bright A_JumpIf(user_lcounter < 17 ,"NuclearFireLoop")
		TNT1 A 1 Bright
		Stop
	}
}

Actor NuclearPillEx : PlanCBoom
{
Renderstyle None
-FOILINVUL
+NOCLIP
+NODAMAGETHRUST
Speed 20
Damagetype "Explosion"
Obituary "%o was burned by in nuclear fire."
States
	{
	Spawn:
		TNT1 A 0
		TNT1 AAAAAAAA 2 A_Explode(2500,1000,true,0,333)
	Death:
		TNT1 A 1
		TNT1 A 1 A_Explode(2500,1000,true,0,166)
		//TNT1 AAA 1 A_CustomMissile("HemNuclearFlare2",0,0,random(0,360),2,random(-90,90))
		TNT1 A 1
		Stop
	}
}

Actor NuclearPillEx2 : PlanCBoom
{
Renderstyle None
Speed 20
-FOILINVUL
+NOCLIP
+NODAMAGETHRUST
Damagetype "Explosion"
Obituary "%o was burned by in nuclear fire."
States
	{
	Spawn:
		TNT1 A 0
		TNT1 AAAAAAAA 2 A_Explode(2500,1000,true,0,333)
	Death:
		TNT1 A 1
		TNT1 A 1 A_Explode(2500,1000,true,0,166)
		TNT1 A 1
		Stop
	}
}

ACTOR PlanN : CustomInventory 32451
{
Inventory.Amount 1
Inventory.MaxAmount 1
Inventory.PickupSound "devilchest/good"
Inventory.UseSound ""
Inventory.PickupMessage "Plan N. When Plan ABCDEFGHIJKLM fails."
Tag "Plan N"
Inventory.Icon "PILNB0"
+INVENTORY.INVBAR
+INVENTORY.NEVERRESPAWN
+COUNTITEM
+FLOORCLIP
+NOTIMEFREEZE
States
	{
Spawn:
    PILN A 1
    Loop
 Use:
	TNT1 A 0
	TNT1 A 0 A_CheckFlag("Invulnerable","NiceTry")
	TNT1 A 1 A_SpawnItemEx("PlanNBoom",0,0,15,0,0,0,0)
	Stop
 NiceTry:
	TNT1 A 0 A_Print("Nice Try! You can't use this item while being invulnerable!")
	Fail
      }
}

ACTOR PlanNBoom
{
  Radius 20
  Height 30
  Damage 100
  Speed 18
  Alpha 0.95
  Scale 2.0
  Renderstyle Add
  Alpha 0.85
  Projectile
  +FORCERADIUSDMG
  +STRIFEDAMAGE
  +THRUSPECIES
  +NOTIMEFREEZE
  +FOILINVUL
  +RIPPER
  +NOBOSSRIP
  //+NODAMAGETHRUST
  +DONTREFLECT
  +SKYEXPLODE
  +THRUGHOST
  +ThruSpecies
  +DontHurtSpecies
  +DontHarmSpecies
  Species "Player"
  Damagetype "NemesisBall"
  DeathSound ""
  Obituary "%o tries to swallow a Plan N medicine."
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_AlertMonsters
  Death:
    TNT1 A 0 A_StopSound(7)
	TNT1 A 0 Radius_Quake(5,60,0,10,0)
	TNT1 A 0 A_Explode(8000,32,true,true,666)
	//UNB2 ABCDABCD 6 Bright A_SpawnItemEx("NemesisAltBallShockwave")
	TNT1 A 0 A_PlaySound("Nemesis/BallExplode",1,1.0,0,0.2)
	TNT1 A 0 A_SpawnItemEx("NemesisHugeExplosion",-40)
	TNT1 A 0 A_SpawnItemEx("NemesisAltBallEx")
	TNT1 A 0 A_Quake(9,100,0,2000,0)
    TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 2 A_Explode(700,5000,0,0,2000)
    Stop    
    }
}

ACTOR SuicideKing : CustomInventory 32452
{
Inventory.Amount 1
Inventory.MaxAmount 1
Inventory.PickupSound "Card/pickup"
Inventory.UseSound ""
Inventory.PickupMessage "Suicide King. The true ending of mortality?"
Tag "Suicide King"
Inventory.Icon "SUKGB0"
+INVENTORY.INVBAR
+INVENTORY.NEVERRESPAWN
+COUNTITEM
+FLOORCLIP
+NOTIMEFREEZE
States
	{
Spawn:
    SUKG A 1
    Loop
 Use:
	TNT1 A 0
	TNT1 A 0 A_CheckFlag("Invulnerable","NiceTry")
	TNT1 A 1 A_SpawnItemEx("SuicideKingBoom",0,0,15,0,0,0,0)
	Stop
 NiceTry:
	TNT1 A 0 A_Print("Nice Try! You can't use this item while being invulnerable!")
	Fail
      }
}

ACTOR SuicideKingBoom : FastProjectile
{
Height 8
Radius 13
Speed 75
Damage 250
+DONTREFLECT
+MTHRUSPECIES
+FORCERADIUSDMG
Damagetype "Explosion"
Obituary "%o got hurt and collapsed while using the Suicide King card."
States
	{
	Spawn:
		TNT1 A 0 NoDelay A_AlertMonsters
	Death:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_Explode(8000,32,true,true,666)
		TNT1 A 0 Bright A_JumpIfInventory("Tic",1,"End")
		TNT1 A 0 Bright A_GiveInventory("Tic",1)
		TNT1 A 0 Bright A_SpawnItemEx("EFGFusionNukeFX",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		TNT1 A 0 Bright A_CustomMissile("EFGFusionNukeExplode",0,0,0,CMF_AIMDIRECTION|CMF_TRACKOWNER,0)
		TNT1 A 0 Bright A_SpawnItemEx("SuperCrateActiveJackpot")
		TNT1 AAAAAAAA 3 Bright A_SpawnItemEx("WelderFlare",0,0,0,random(2,4),random(2,4),2,random(0,360),SXF_NOCHECKPOSITION|SXF_TRANSFERPOINTERS|SXF_SETMASTER,64)
		Stop
	End:
		TNT1 A 1 Bright
		Stop
	}
}