actor CamSuperShotgun : Weapon
{
  Weapon.AmmoUse 2
  Weapon.AmmoGive 8
  Weapon.AmmoType "CamShell"
  Inventory.PickupMessage "$GOTSHOTGUN2"
  Obituary "%o was blasted by %k's Double Shotgun."
  Tag "Double Shotgun"
  Decal "BulletChip"
  Inventory.RestrictedTo "CameronClass"
  States
  {
  Ready:
    CADS A 1 A_WeaponReady
    Loop
  Deselect:
    CADS A 1 A_Lower
	TNT1 A 0 A_Lower
	TNT1 A 0 A_Lower
    Loop
  Select:
    CADS A 1 A_Raise
	TNT1 A 0 A_Raise
	TNT1 A 0 A_Raise
    Loop
  Fire:
    CADS A 3
	CADS A 0 A_Recoil (2)
	CADS A 0 A_FireBullets (12, 12, 24, 7, "CameronAcidicBulletPuff")
    CADS A 0 A_PlaySound ("weapons/camssgfire", CHAN_WEAPON)
    CADS B 7 A_GunFlash
    CADS C 3 
	TNT1 A 0 A_JumpIfNoAmmo ("Ready")
    CADS D 3 A_PlaySound ("weapons/camssgopn")
    CADS E 3 
    CADS F 3
    CADS G 3
    CADS H 3
    CADS I 3 
	CADS J 3 A_PlaySound ("weapons/camssgload")
	CADS K 3
	CADS L 3 A_PlaySound ("weapons/camssgload")
	CADS M 3
	CADS N 3 A_PlaySound ("weapons/camssgcls")
	CADS O 3
	CADS P 3
	CADS Q 3
	CADS R 3
    CADS A 3 A_ReFire
    Goto Ready
  Flash:
    CADF A 4 Bright A_Light1
    TNT1 A 3 Bright A_Light2
    Goto LightDone
  Spawn:
    CSSW A -1
    Stop
  }
}
