actor NanoRocketLauncher : Weapon
{
  Weapon.SelectionOrder 9998
  Weapon.AmmoUse 1
  Weapon.AmmoGive 2
  Weapon.AmmoType "RocketAmmo"
  Tag "Cluster Launcher"
  Inventory.RestrictedTo "MorseClass"
  Inventory.Pickupmessage "Picked up a Rocket Launcher." // "Picked up a Rocket Launcher."
  States
  {
  Ready:
	NARL A 1 A_WeaponReady
    loop
  Deselect:
    NARL A 1 A_Lower
	TNT1 A 0 A_Lower
	TNT1 A 0 A_Lower
	Loop
  Select:
	NARL A 1 A_Raise
	TNT1 A 0 A_Raise
	TNT1 A 0 A_Raise
    Loop
  Fire:
    NARL A 4 A_PlayWeaponSound("weapons/nanoRL/fire1")
	NARL A 0
	NARL A 1 bright A_GunFlash
	NARL B 1 bright A_Recoil(2.3)
    NARL C 1 bright
	NARL D 1 bright
	NARL E 1 bright
	NARL O 2
	NARL P 3
	NARL O 2
	NARL E 1
	NARL D 1
	NARL C 1
	NARL B 1
	NARL A 1 A_ReFire
    Goto Ready
  Spawn:
    LAUN A -1
    Stop
  Flash:
    D3RF A 1 BRIGHT 
    D3RF B 1 BRIGHT A_FireCustomMissile("NanoRocket", 0, 1, 1, 0)
    D3RF C 1 BRIGHT Radius_Quake(5,4,0,1,0)
    D3RF D 1 BRIGHT
    D3RF E 1 BRIGHT
      Stop
  }
}

ACTOR NanoRocket
{
	Radius 10
	Height 8
	Speed 75
	Damage 20
	Projectile
	-NOGRAVITY
	+RANDOMIZE
	+Friendly
	Species "Player"
	DeathSound "weapons/NanoRL/explode"
	Obituary  "%o was gibbed by %k's rocket."
	States
	{
	Spawn:
		MIS3 A 0
		MIS3 A 0 A_PlaySoundEx("weapons/NanoRL/rocketloop","weapon",1)
		MIS3 A 5 BRIGHT A_CustomMissile("ZOOMIES4",5,0,0,0)
		TNT1 A 0 BRIGHT A_Mushroom ("NanoMiniRocket",4,MSF_DontHurt)
		Loop
	Death:
		MISL B 0 bright
		MISL B 0 bright A_StopSoundEx("weapon")
		TNT1 A 0 BRIGHT A_Mushroom ("NanoMiniRocket",3,MSF_DontHurt,2)
		TNT1 A 0 BRIGHT A_Mushroom ("NanoMiniRocket",6,MSF_DontHurt,2,0.6)
		TNT1 A 0 BRIGHT A_Mushroom ("NanoMiniRocket",12,MSF_DontHurt,2,0.7)
		TNT1 A 0 BRIGHT A_Mushroom ("NanoMiniRocket",24,MSF_DontHurt,2,0.8)
		MISL B 0 bright A_Explode (250,250)
		MISL B 4 bright 
		MISL C 4 bright Radius_Quake(3,5,0,16,0)
		MISL D 4 bright
		Stop
	}
}

ACTOR NanoMiniRocket : NanoRocket
{
	Radius 10
	Height 8
	Speed 15
	Damage 5
	Scale .5
	Projectile
	-NOGRAVITY
	+RANDOMIZE
	+Friendly
	Species "Player"
	DeathSound "scatter/explode"
	Obituary  "%o was splattered by %k's minirocket."
		States
	{
	Spawn:
		MIS3 A 0
		MIS3 A 0 A_PlaySoundEx("scatter/missile","weapon",1)
		MIS3 A 2 BRIGHT A_CustomMissile("ZOOMIES4",5,0,0,0)
		Loop
	Death:
		MISL B 0 bright
		MISL B 0 bright A_StopSoundEx("weapon")
		MISL B 0 bright A_Explode (25,100,1,0,25)
		MISL B 4 bright 
		MISL C 4 bright Radius_Quake(3,5,0,16,0)
		MISL D 4 bright
		Stop
	}
}