Actor AFTERTRAIL : BulletPuff
{
  +ClientSideOnly
  SCALE 0.3
  States
  {
  Spawn:
    FLXP ABC 2 BRIGHT
    Stop
  }
}
ACTOR TankRocket
{
  Radius 11
  Height 8
  Speed 50
  Damage 90
  Projectile
  +RANDOMIZE
  +DEHEXPLOSION
  +EXTREMEDEATH
  SeeSound "TANKFR2"
  DeathSound "TANKBOOM"
  Obituary  "%o was blasted by %k's PSKA rocket."
  SelfObituary "%o experienced danger close."
  DamageType "BoomerExplosive2"
  States
  {
  Spawn:
    TIS2 A 1 A_CustomMissile("AFTERTRAIL", 3, 0, 0, 1)
    Loop
  Death:
    TNT1 AA 0 A_SpawnItemEx ("EXPLOTA2",0,0,0,2,0,random(-2,2),random(0,359))
    TNT1 AAAAA 0 A_SpawnItemEx ("EXPLOTA2",0,0,0,2,0,random(-3,3),random(0,359))
  TNT1 A 0 a_Quake(3,10,0,5000,0)
    Stop
  }
}

Actor Explota2
{
    +FORCEXYBILLBOARD
    +BRIGHT
    +NOINTERACTION
	+EXTREMEDEATH
	+ForceRadiusDMG
	DamageType "BoomerExplosive"
    Scale 3
    Alpha 0.9
    Renderstyle "Add"
	Obituary  "%o was blasted by %k's PSKA rocket."
	SelfObituary "%o experienced danger close."
    States
    {
    Spawn:
        FTX1 A 0
        FTX1 A 0
		TNT1 A 0 A_Explode(250, 200, 1)
        MISL BBBCCCDDD 1 A_FadeOut(0.05,1)
        Stop
    }
}

ACTOR BoomerTankCannon : Weapon
{
  Weapon.SelectionOrder 1900
  Weapon.AmmoUse 1
  Weapon.AmmoGive 1
  Weapon.AmmoType "BoomerRockets"
  Inventory.PickupMessage "You got The Katyusha Cannon! I AM THE PSKA!"
  Tag "20.764 MM Katyusha Cannon"
  DECAL "SCORCH"
  Inventory.RestrictedTo "BoomerClass"
  States
  {
  Ready:
    PSKA A 2 OFFSET(9,128)
	PSKA A 2 OFFSET(7,96)
	PSKA A 2 OFFSET(5,72)
	PSKA A 2 OFFSET(3,48)
	PSKA A 2 OFFSET(1,36)
    GOTO READY2
	Ready2:
    PSKA A 1 A_WeaponReady
    Loop
  Deselect:
    PSKA AA 0 A_Lower
	PSKA A 2 A_Lower
    Loop
  Select:
    PSKA AA 0 A_Raise
	PSKA A 0 A_Raise
    Loop
  Fire:
    PSKA A 2 OFFSET(0,36)
	TNT1 A 0 A_PLAYSOUND("TANKFR1", CHAN_AUTO)
	PSKA B 0 A_GUNFLASH
	PSKA B 2 BRIGHT OFFSET(0,37) A_FIRECUSTOMMISSILE("TANKROCKET")
	PSKA C 4 OFFSET(0,39)
	PSKA D 4 OFFSET(0,36) 
	PSKA E 4 OFFSET(0,34)
	PSKA A 15 OFFSET(0,32)
	TNT1 A 0 A_PLAYSOUND("TANKCHRG", CHAN_AUTO)
	PSKA A 2 OFFSET(0,36)
	PSKA A 2 OFFSET(0,39)
	PSKA A 2 OFFSET(0,42)
	PSKA A 2 OFFSET(0,44)
	PSKA A 6 OFFSET(0,46)
	PSKA A 2 OFFSET(0,44)
	PSKA A 2 OFFSET(0,42)
	PSKA A 2 OFFSET(0,39)
	PSKA A 2 OFFSET(0,36)
	PSKA A 4 OFFSET(0,32)
    Goto Ready2
  Spawn:
    PIST A -1
    Stop
  }
}

Actor BoomerRockets : Ammo
{
	Inventory.Amount 1
	Inventory.Maxamount 10
	Ammo.Backpackamount 1
	Ammo.BackpackMaxamount 20
}