ACTOR SSG : BrutalWeapon
{
	Game Doom
	SpawnID 33
	Weapon.Kickback 50
	Weapon.SelectionOrder 400
	Weapon.AmmoGive1 0
	Weapon.AmmoGive2 0
	Weapon.AmmoType1 "AmmoShell"
	Weapon.AmmoType2 "SSGAmmo"
	Weapon.AmmoUse1 0
	Weapon.AmmoUse2 0
	+WEAPON.NOAUTOAIM
	+WEAPON.NOAUTOFIRE
	+FORCEXYBILLBOARD
	Inventory.PickupMessage "$GOTSHOTGUN2"
	Obituary "$OB_MPSSHOTGUN"
	Inventory.PickupSound "CLIPINSS"
	YScale 0.8
	XScale 1.0
	Tag "Super Shotgun"
	DropItem "SSGSpawner"
	States
	{
    SelectAnimation:
	Ready:
	Ready3:
	    SHTZ A 1 A_WeaponReady(WRF_ALLOWRELOAD)
        SHTZ A 0 A_JumpIfInventory("Kicking",1,"DoKick")
        SHTZ A 0 A_JumpIfInventory("Taunting",1,"Taunt")
		SHTZ A 0 A_JumpIfInventory("Salute1", 1, "Salute")
		SHTZ A 0 A_JumpIfInventory("Salute2", 1, "Salute")
		SHTZ A 0 A_JumpIfInventory("Reloading",1,"Reload")
		SHTZ A 0 A_JumpIfInventory("Unloading",1,"Unload")
		SHTZ A 0 A_JumpIfInventory("StartDualWield",1,"ChangeShell")
		SHTZ A 0 A_JumpIfInventory("TossGrenade",1,"TossGrenade")
		TNT1 A 0 A_JumpIfInventory("ExecuteDownedEnemy", 1, "DoExecution")
		SHTZ A 0 A_JumpIfInventory("IsRunning",1,"StartSprint")
		Loop

	ChangeShell:
		TNT1 A 0 A_TakeInventory("StartDualWield", 1)
		TNT1 A 0 A_GiveInventory("ShotgunChangeAmmo", 1)
        TNT1 A 0 A_ZoomFactor(1.0)
		TNT1 A 0 A_JumpIfInventory("AmmoSlug", 1, "Unload")
		Goto NoSlugs

	NoSlugs:
		TNT1 A 0 A_Print("You are out of shotgun slugs.", 2)
		SHTN A 0 A_TakeInventory("ShotgunChangeAmmo",1)
		SHTZ A 3
		Goto Ready

	StartSprint:
		SHTZ A 1 A_WeaponReady(WRF_ALLOWRELOAD)
		SHTN A 0 A_Takeinventory("Zoomed",1)
        SHTN A 0 A_ZoomFactor(1.0)
		SHTN A 0 A_Takeinventory("ADSmode",1)
		RIFG A 0 A_SetCrosshair(0)
		SHTN A 0 A_Giveinventory("GoSpecial",1)
		TNT1 A 0 ACS_NamedExecuteAlways("BDSprint", 0, 0, 0, 0)//Makes player faster.)

	Sprinting:
		SSRU A 1 offset(-9,34) A_SetPitch(pitch -0.5)
		SSRU A 1 offset(-6,36) A_SetPitch(pitch -0.5)
		SSRU A 1 offset(-3,38) A_SetPitch(pitch -0.5)
		SSRU A 1 offset(0,38) A_SetPitch(pitch -0.5)
		SSRU A 1 offset(3,36) A_SetPitch(pitch -0.5)
		SSRU A 1 offset(6,34) A_SetPitch(pitch -0.5)
		SSRU A 1 offset(9,32) A_SetPitch(pitch -0.5)
		TNT1 A 0 A_GiveInventory("UsedStamina", 2)
		SMGG A 0 A_WeaponReady(WRF_NOBOB)
		SMGG A 0 A_JumpIfInventory("Kicking",1,"DoKick")
        SMGG A 0 A_JumpIfInventory("Taunting",1,"Taunt")
        SMGG A 0 A_JumpIfInventory("Reloading",1,"Reload")

		SSRU A 1 offset(9,34) A_SetPitch(pitch +0.5)
		SSRU A 1 offset(6,36) A_SetPitch(pitch +0.5)
		SSRU A 1 offset(3,38) A_SetPitch(pitch +0.5)
		SSRU A 1 offset(0,38) A_SetPitch(pitch +0.5)
		SSRU A 1 offset(-3,36) A_SetPitch(pitch +0.5)
		SSRU A 1 offset(-6,34) A_SetPitch(pitch +0.5)
		SSRU A 1 offset(-9,32) A_SetPitch(pitch +0.5)
		TNT1 A 0 A_GiveInventory("UsedStamina", 2)
		SMGG A 0 A_WeaponReady(WRF_NOBOB)
		SMGG A 0 A_JumpIfInventory("Kicking",1,"DoKick")
        SMGG A 0 A_JumpIfInventory("Taunting",1,"Taunt")
        SMGG A 0 A_JumpIfInventory("Reloading",1,"Reload")

		PLAY A 0 ACS_NamedExecuteAlways("BDSprint", 0, 0, 0, 0)//Makes player faster.
		SMGG A 0 A_JumpIfInventory("IsRunning", 1, "Sprinting")
		Goto StopSprint

	StopSprint:
		SSRU A 0 A_JumpIfInventory("PowerStrength", 1, 2)
		SHTZ A 0 A_JumpIfInventory("UsedStamina", 100, "StopSprintTired")
		SSRU A 1 ACS_NamedExecuteAlways("BDTacticalSpeed", 0, 0, 0, 0)//Makes player slower.
		Goto Ready

	StopSprintTired:
		SSRU A 1 ACS_NamedExecuteAlways("BDTacticalSpeed", 0, 0, 0, 0)//Makes player slower.
		SHTZ A 0 A_PlaySound("Tired", 2)
		Goto Ready

	Deselect:
		SHTZ A 0 A_Takeinventory("Zoomed",1)
        SHTZ A 0 A_ZoomFactor(1.0)
		SHTZ A 0 A_TakeInventory("TossGrenade", 1)
		SHT5 DCBA 1
		TNT1 AAAAAAAAAAAAAAAAAA 0 A_Lower
		TNT1 A 1 A_Lower
		Wait

	Select:
		SHTZ A 0 A_Giveinventory("GoSpecial",1)
		TNT1 A 0 A_TakeInventory("FistsSelected", 1)
		TNT1 A 0 A_TakeInventory("ShotgunSelected", 1)
		TNT1 A 0 A_TakeInventory("MinigunSelected", 1)
		TNT1 A 0 A_GiveInventory("SSGSelected", 1)
		TNT1 A 0 A_TakeInventory("RocketLauncherSelected", 1)
		TNT1 A 0 A_TakeInventory("GrenadeLauncherSelected", 1)
		TNT1 A 0 A_TakeInventory("PlasmaGunSelected", 1)
		TNT1 A 0 A_TakeInventory("RailGunSelected", 1)
		TNT1 A 0 A_TakeInventory("RevenantLauncherSelected", 1)
		TNT1 A 0 A_TakeInventory("SubMachineGunSelected", 1)
		TNT1 A 0 A_TakeInventory("BFG10KSelected", 1)
		TNT1 A 0 A_TakeInventory("BFGSelected", 1)
		TNT1 A 0 A_TakeInventory("FlameCannonSelected", 1)
		TNT1 A 0 A_TakeInventory("SawSelected", 1)
		SHTZ A 0 A_Takeinventory("HasBarrel",1)
		SHTZ A 0 A_TakeInventory("TossGrenade", 1)
		SHTZ A 0 A_TakeInventory("SSG2", 1)
		TNT1 AAAAAAAAAAAA 0 A_Raise
		SHTZ A 0 A_GunFlash
		SHTZ A 0 A_JumpIfInventory("SSGAmmo", 1, 1)
		Goto RaiseReloading
		SHT5 ABCD 1
		SHTZ A 0 A_PlaySound("weapons/sshotc")
		Goto Ready

	RaiseReloading:
		SHTZ A 0
		SHTZ A 0 A_JumpIfInventory("AmmoShell", 2, 1)
		Goto RaiseNoAmmo
		SHTZ L 1 Offset(0,40)
		SHTZ M 1 Offset(0,38)
		SHTZ N 1 Offset(0,36)
		SHTZ O 1 Offset(0,34)
		SHTZ A 0 A_playsound("weapons/sshotl")
		SHTZ P 2 Offset(10,36)
		SHTZ P 2 Offset(20,46)
		SHTZ Q 1 Offset(30,56)
		SHTZ Q 1 Offset(40,66)
		SHTZ R 1 Offset(50,76)
		SHTZ S 1
		SHTZ A 0 A_GiveInventory ("Pumping", 1)

		SHTZ T 1 Offset(30,56)
		SHTZ U 1 Offset(20,46)
		SHTZ V 1 Offset(1,33)

		SHTZ A 0 A_GiveInventory ("Pumping", 1)
		SHTZ A 0 A_PlaySound("weapons/sshotc")
		SHTZ A 0 A_TakeInventory("AmmoShell", 2)
		SHTZ A 0 A_GiveInventory("SSGAmmo", 2)

		SHTZ WXYZ 1
		SHTZ A 0 A_TakeInventory ("Pumping", 1)
		SHTZ A 0 A_TakeInventory ("SSGUnloaded", 1)
		SHTZ A 0 A_TakeInventory("SSGAlt",1)
		TNT1 A 0 A_TakeInventory("ShotgunChangeAmmo",1)
		SHO9 DEFG 1
		SHTZ A 0 A_ReFire
		SHTZ A 2
		Goto Ready

	RaiseNoAmmo:
		SHT5 ABCD 1
		SHTZ A 0 A_PlaySound("weapons/sshotc")
		Goto Ready

	NoAmmo:
		SHTZ A 0
		SHTZ A 0 A_ZoomFactor(1.0)
		SHTZ A 0 A_Takeinventory("Zoomed",1)
		SHTZ A 0 A_Takeinventory("ADSmode",1)
		TNT1 A 0 A_PlaySound("weapons/empty", 4)
		NoAmmo2:
		SHTZ A 0 A_JumpIfInventory("TossGrenade",1,"TossGrenade")
	    SHTZ A 0 A_JumpIfInventory("Taunting",1,"Taunt")
		SHTZ A 0 A_JumpIfInventory("Salute1", 1, "Salute")
		SHTZ A 0 A_JumpIfInventory("Salute2", 1, "Salute")
		SHTZ A 0 A_JumpIfInventory("ExecuteDownedEnemy", 1, "DoExecution")
		SHTZ A 0 A_JumpIfInventory("Kicking",1,"DoKick")
		SHTZ A 5 A_WeaponReady(WRF_ALLOWRELOAD | WRF_NOFIRE)
		SHTZ A 0 A_JumpIfInventory("Reloading",1,"Reload")
		TNT1 A 0 A_JumpIfInventory("NoAutoReload", 1, 2)
		SHTZ A 0 A_JumpIfInventory("AmmoShell",1,"Reload")
		SHTZ A 0 A_JumpIfInventory("IsRunning",1,"StartSprint")
		Goto Ready3

	 Fire:
		SHTZ A 0 A_TakeInventory("Reloading",1)
		SHTZ A 0 A_JumpIfInventory("SSGAmmo", 2, 2)
		SHTZ A 0 A_JumpIfInventory("SSGAmmo", 1, "AltFire")
		Goto NoAmmo

		SHTZ A 0 A_TakeInventory("SSGAmmo", 2)
		SHTZ A 0 A_JumpIfInventory("PowerStrength", 1, 2)
		SHTZ A 0 A_Recoil(3)
		SHTZ A 0
		SHTZ A 0 A_FireCustomMissile("DistantFireSoundSSG", random(-1,1), 0, 0, -12, 0, random(-1,1))
		SHO9 A 0 A_firebullets (0,0,1,40,"shotpuff",FBF_NORANDOM,128)
        SHO9 A 0 BRIGHT A_playsound("SSHFIRE", 1)
		TNT1 AAAAAAAAAAA 0 A_FireCustomMissile("DecorativeTracer", random(-6,6), 0, 0, 0, 0, random(-3,3))
		TNT1 AAAAAAAAAAAAAAAAAAAA 0 BRIGHT A_FireCustomMissile("ShotgunParticles", random(-18,18), 0, -1, 0, 0, random(-9,9))
		TNT1 AAAAAAAAAAAAA 0 BRIGHT A_FireCustomMissile("ShotgunParticles2", random(-18,18), 0, -1, 0, 0, random(-9,9))
		SHTZ A 0 A_SpawnItemEx("PlayerMuzzle1",32,0,28)
		TNT1 A 0 A_FireCustomMissile("Alerter",0,0)
		SHOF A 1 BRIGHT
		SHTZ A 0 A_FireBullets (5.6, 2.8, 9, 13, "ShotgunPuff", FBF_NORANDOM)
		SHTZ A 0 A_FireBullets (5.6, 2.8, 9, 13, "ShotgunPuff", FBF_NORANDOM)
		TNT1 A 0 A_ZoomFactor(0.96)
		SHTZ A 0 A_JumpIfInventory("IsNOTTacticalClass", 1, 3)//Tactical Mode deals extra damage and recoil
		SHTN A 0 A_FireBullets (5.6, 2.8, 10, 13, "ShotgunPuff2", FBF_NORANDOM)
		SHTZ A 0 A_SetPitch(pitch-3.6)
		SHTZ A 0 A_SetPitch(pitch-3.6)
        SHOF B 1 BRIGHT
		TNT1 A 0 A_ZoomFactor(1.0)
        SHTZ A 0 A_TakeInventory("SSGAlt",1)
        SHTZ A 0 A_TakeInventory("Reloading",1)

		SHOF CDEFGI 1 A_SetPitch(pitch+0.6)

		SHTZ A 0 A_JumpIfInventory("Reloading",1,"Reload")
		SHTZ A 0 A_JumpIfInventory("Kicking",1,"DoKick")
        SHTZ A 0 A_JumpIfInventory("Taunting",1,"Taunt")
		SHTZ A 0 A_JumpIfInventory("Salute1", 1, "Salute")
		SHTZ A 0 A_JumpIfInventory("Salute2", 1, "Salute")
		SHTZ A 0 A_JumpIfInventory("TossGrenade",1,"TossGrenade")
		SHTZ A 1 A_WeaponReady(WRF_NOFIRE | WRF_NOBOB)
		TNT1 A 0 A_JumpIfInventory("NoAutoReload", 1, 2)//Don't go to NoAmmo unless they try to fire again
		Goto NoAmmo2
		TNT1 AA 0
		Goto Ready

	Reload:	//both barrels
		SHTZ A 0
		SHTZ A 0 A_TakeInventory("Reloading",1)
		SHTZ A 0 A_JumpIfInventory("AmmoShell", 1, 1)//Check if has any shells in inventory
		Goto Ready
		SHTZ A 0 A_JumpIfInventory("AmmoShell", 2, 1)//Check if has two shells to reload both barrels
		Goto Reload2

		SHTZ A 0 A_JumpIfInventory("SSGAlt", 1, "Reload2")//Check if right shell has been fired
		SHTZ A 0 A_JumpIfInventory("SSGAmmo", 2, "Ready")//Check if both barrels are loaded
		SHTZ A 0 A_JumpIfInventory("SSGAmmo", 1, "Reload2")

		SHTZ B 1 Offset(20,48)
		SHTZ B 1 Offset(10,36)
		SHTZ BCDEFGHIJ 1 A_WeaponReady(WRF_NOBOB | WRF_NOFIRE)
		A12R A 0 A_JumpIfInventory("Kicking",1,"DoKick")
		SHTZ A 0 A_GiveInventory ("Pumping", 1)

		SHTZ A 0 A_PlaySound("weapons/sshotc")
		SHTZ A 0 A_JumpIfInventory("SSGUnloaded", 1, 3)
		TNT1 AA 0 A_FireCustomMissile("SSGCaseSpawner",0,0,-8, -8)
		SHTZ KL 1 A_WeaponReady(WRF_NOBOB | WRF_NOFIRE)
		A12R A 0 A_JumpIfInventory("Kicking",1,"DoKick")
		SHTZ L 8 A_WeaponReady(WRF_NOBOB | WRF_NOFIRE)
		A12R A 0 A_JumpIfInventory("Kicking",1,"DoKick")
		SHTZ MNO 1
		SHTZ A 0 A_playsound("weapons/sshotl")
		SHTZ P 2 Offset(10,36)
		SHTZ P 2 Offset(20,46)
		SHTZ Q 1 Offset(30,56)
		SHTZ Q 1 Offset(40,66)
		SHTZ R 1 Offset(50,76)
		SHTZ S 1
		SHTZ A 0 A_GiveInventory ("Pumping", 1)

		SHTZ T 1 Offset(30,56)
		SHTZ U 1 Offset(20,46)
		SHTZ V 1 Offset(1,33)

		SHTZ A 0 A_GiveInventory ("Pumping", 1)
		SHTZ A 0 A_PlaySound("weapons/sshotc")
		SHTZ A 0 A_TakeInventory("AmmoShell", 2)
		SHTZ A 0 A_GiveInventory("SSGAmmo", 2)

		SHTZ WXYZ 1
		SHTZ A 0 A_TakeInventory ("Pumping", 1)
		SHTZ A 0 A_TakeInventory ("SSGUnloaded", 1)
		SHTZ A 0 A_TakeInventory("SSGAlt",1)
		TNT1 A 0 A_TakeInventory("ShotgunChangeAmmo",1)
		SHO9 DEFG 1
		SHTZ A 0 A_ReFire
		SHTZ A 2
		Goto Ready

	AltFire:
		SHTZ A 0 A_TakeInventory("Reloading",1)
		SHTZ A 0 A_JumpIfInventory("SSGAmmo",1,3)
        Goto NoAmmo
        TNT1 AAAAA 0
		SHTZ A 0 A_JumpIfInventory("SSGAlt",1,"AltFire2")

		SHTZ A 0 A_TakeInventory("SSGAmmo",1)
		SHTZ A 0 A_GiveInventory("SSGAlt",1)
        SHTU A 1 BRIGHT A_FireBullets (2.7, 2.8, 9, 13, "ShotgunPuff", FBF_NORANDOM)
		SHTZ A 0 A_ALertMonsters
		TNT1 AAAAAAAAAAAAAAAA 0 BRIGHT A_FireCustomMissile("ShotgunParticles", random(-12,12), 0, -1, 0, 0, random(-9,9))
		TNT1 AAAAA 0 BRIGHT A_FireCustomMissile("ShotgunParticles2", random(-12,12), 0, -1, 0, 0, random(-9,9))
		TNT1 AAAAA 0 A_FireCustomMissile("DecorativeTracer", random(-3,3), 0, 0, 0, 0, random(-3,3))
        SHTU A 0 BRIGHT A_PlaySound("weapons/sg", 1)
		SHTZ A 0 A_SpawnItemEx("PlayerMuzzle1",32,0,28)
		SHTZ A 0 A_FireCustomMissile("DistantFireSoundShotgun", random(-1,1), 0, 0, -12, 0, random(-1,1))
		TNT1 A 0 A_ZoomFactor(0.98)
		SHTZ A 0 A_JumpIfInventory("IsNOTTacticalClass", 1, 3)//Tactical Mode deals extra damage and recoil
		SHTN A 0 A_FireBullets (2.7, 2.8, 5, 13, "ShotgunPuff2", FBF_NORANDOM)
		SHTZ A 0 A_SetPitch(pitch-1.8)
		SHTZ A 0 A_SetPitch(pitch-1.8)
		SHTZ A 0
		SHOF E 1 A_SetPitch(0.3 + pitch)
		TNT1 A 0 A_ZoomFactor(1.0)
		SHOF FGHI 1 A_SetPitch(0.3 + pitch)
        SHTZ A 1 A_SetPitch(0.3 + pitch)
        Goto Ready

	AltFire2:
		SHTZ A 0 A_TakeInventory("SSGAmmo",1)
        SHTU B 1 BRIGHT A_FireBullets (2.7, 2.8, 9, 13, "ShotgunPuff", FBF_NORANDOM)
		SHTZ A 0 A_ALertMonsters
		TNT1 AAAAAAAAAAAAAAAA 0 BRIGHT A_FireCustomMissile("ShotgunParticles", random(-12,12), 0, -1, 0, 0, random(-9,9))
		TNT1 AAAAA 0 BRIGHT A_FireCustomMissile("ShotgunParticles2", random(-12,12), 0, -1, 0, 0, random(-9,9))
		TNT1 AAAAA 0 A_FireCustomMissile("DecorativeTracer", random(-3,3), 0, 0, 0, 0, random(-3,3))
        SHTU A 0 BRIGHT A_PlaySound("weapons/sg", 1)
		SHTZ A 0 A_SpawnItemEx("PlayerMuzzle1",32,0,28)
		SHTZ A 0 A_FireCustomMissile("DistantFireSoundShotgun", random(-1,1), 0, 0, -12, 0, random(-1,1))
		TNT1 A 0 A_ZoomFactor(0.98)
		SHTZ A 0 A_JumpIfInventory("IsNOTTacticalClass", 1, 3)//Tactical Mode deals extra damage and recoil
		SHTN A 0 A_FireBullets (2.7, 2.8, 5, 13, "ShotgunPuff2", FBF_NORANDOM)
		SHTZ A 0 A_SetPitch(pitch-1.8)
		SHTZ A 0 A_SetPitch(pitch-1.8)
		SHTZ A 0
		SHOF E 1 A_SetPitch(0.3 + pitch)
		TNT1 A 0 A_ZoomFactor(1.0)
		SHOF FGHI 1 A_SetPitch(0.3 + pitch)
        SHTZ A 1 A_SetPitch(0.3 + pitch)

		SHTZ A 0 A_TakeInventory("SSGAlt", 1)
		TNT1 A 0 A_JumpIfInventory("NoAutoReload", 1, 2)//Don't go to NoAmmo unless they try to fire again
		Goto Reload
		TNT1 AA 0
		Goto Ready

	Reload2://one barrel
		SHTZ A 0 A_TakeInventory("Reloading",1)
		SHTZ A 0 A_TakeInventory("SSGAlt",1)
		SHTZ A 0 A_JumpIfInventory("SSGAmmo", 2, "Ready")//Check if both barrels are loaded

		SHTZ B 1 Offset(20,48)
        SHTZ B 1 Offset(10,36)
		SHTZ BCDEFGHIJ 1 A_WeaponReady(WRF_NOBOB | WRF_NOFIRE)
		A12R A 0 A_JumpIfInventory("Kicking",1,"DoKick")
		SHTZ A 0 A_GiveInventory ("Pumping", 1)

        SHTZ A 0 A_PlaySound("weapons/sshotc")
		SHTZ A 0 A_FireCustomMissile("SSGCaseSpawner",0,0,-8, -8)
        SHTZ KL 1 A_WeaponReady(WRF_NOBOB | WRF_NOFIRE)
		A12R A 0 A_JumpIfInventory("Kicking",1,"DoKick")
		SHT7 L 8 A_WeaponReady(WRF_NOBOB | WRF_NOFIRE)
		A12R A 0 A_JumpIfInventory("Kicking",1,"DoKick")
		SHT7 MNO 1
        SHTZ A 0 A_playsound("weapons/sshotl")
		SHT7 P 2 Offset(10,36)
		SHT7 P 2 Offset(20,46)
		SHTZ Q 1 Offset(30,56)
		SHTZ Q 1 Offset(40,66)
		SHTZ R 1 Offset(50,76)
		SHTZ S 1
		SHTZ A 0 A_GiveInventory ("Pumping", 1)

		SHTZ T 1 Offset(30,56)
		SHTZ U 1 Offset(20,46)
		SHTZ V 1 Offset(1,33)

		SHTZ A 0 A_GiveInventory ("Pumping", 1)
        SHTZ A 0 A_PlaySound("weapons/sshotc")
		SHTZ A 0 A_TakeInventory("AmmoShell", 1)
		SHTZ A 0 A_GiveInventory("SSGAmmo", 1)

        SHTZ WXYZ 1
		SHTZ A 0 A_GiveInventory ("Pumping", 1)
		SHTZ A 0 A_TakeInventory("SSGAlt",1)
		SHO9 DEFG 1
		SHTZ A 0 A_ReFire
		SHTZ A 2

	  Goto Ready

	Spawn:
		SGN2 A -1
		Stop

	Unload:
		SHTZ A 1 A_WeaponReady
		SHTZ A 0 A_ZoomFactor(1.0)
		SHTZ A 0 A_Takeinventory("Unloading",1)
		SHTZ A 0 A_Takeinventory("ADSmode",1)
		SHTZ A 0 A_Takeinventory("Zoomed",1)
        SHTZ A 0 A_JumpIfInventory("SSGAmmo",1,3)
		TNT1 A 0 A_JumpIfInventory("ShotgunChangeAmmo", 1, "FinishUnload")
        Goto Ready
        TNT1 AAA 0
		SHTZ B 1 Offset(20,48)
        SHTZ B 1 Offset(10,36)
		SHTZ BCDEFGHIV 1 A_WeaponReady(WRF_NOBOB | WRF_NOFIRE)
		A12R A 0 A_JumpIfInventory("Kicking",1,"DoKick")
		SHTZ A 0 A_PlaySound("weapons/sshotc")
		SHTZ UTSQR 1 A_WeaponReady(WRF_NOBOB | WRF_NOFIRE)
		A12R A 0 A_JumpIfInventory("Kicking",1,"DoKick")
		SHTZ A 0 A_playsound("weapons/sshotl")
		SHTZ P 2 Offset(10,36)
		SHTZ P 2 Offset(20,46)
		SHTZ O 1 Offset(30,56)
		SHTZ O 1 Offset(40,66)
		SHTZ N 1 Offset(50,76)
		SHTZ M 1 Offset(40,66)
		SHTZ L 8 Offset(30,56)

	RemoveBullets:
		TNT1 AAAA 0
		SHTZ A 0 A_JumpIfInventory("SSGAmmo",1,3)
		Goto FinishUnload
        TNT1 AAAAAA 0
		SHTZ A 0 A_Takeinventory("SSGAmmo",1)
		SHTZ A 0 A_Giveinventory("AmmoShell",1)
		Goto RemoveBullets

	FInishUnload:
		SHTZ A 0
		SHTZ I 1 Offset(20,46)
		SHTZ A 0 A_PlaySound("weapons/sshotc")
		SHTZ WXYZ 1
		SHO9 DEFG 1
		SHTZ A 0 A_GiveInventory("SSGUnloaded", 1)
		SHTZ A 0 A_Takeinventory("Unloading",1)
		SHTZ A 0 A_TakeInventory("SSGAlt",1)
		TNT1 A 0 A_JumpIfInventory("ShotgunChangeAmmo", 1, "ChangeAmmo")
		Goto Ready

	ChangeAmmo:
		TNT1 A 0
		TNT1 A 0 A_GiveInventory("SSG2")
		TNT1 A 0 A_GiveInventory("Reloading",1)
		TNT1 A 0 A_SelectWeapon("SSG2")
		Goto Ready3
	}
}

ACTOR SSGAmmo : Ammo
{
   Inventory.Amount 0
   Inventory.MaxAmount 2
   Ammo.BackpackAmount 0
   Ammo.BackpackMaxAmount 2
   Inventory.Icon "SGN2A0"
}