Actor TechLamp1 : TechLamp replaces TechLamp
{
	damagefactor "Avoid", 0.0    damagefactor "Kick", 0.0	damagefactor "Melee", 0.0
	damagefactor "KillMe", 0.0 damagefactor "Trample", 0.0 damagefactor "Stealth", 0.0
	+RANDOMIZE
	Mass 65535
	+SHOOTABLE
	+NOBLOOD
	+GHOST
	+SOLID
	health 15
	deathheight 80
	+FORCEYBILLBOARD
	states
	{
	Vanilla:
		TLMP ABCD 2 BRIGHT
		Loop

	Spawn:
		TLMP A 1
		MARN A 0 ACS_NamedExecuteAlways("BDCheckDecorations", 0, 0, 0, 0)//Check if advanced decorations are disabled.
		TNT1 A 1

	Stay:
		TLMP AB 2 bright A_SpawnItemEx("LensFlareAlt", 0, 0, 71)
		TLMP CD 2 bright A_SpawnItemEx("LensFlareAlt", 0, 0, 71)
		Loop

	Death:
		TLMP E 1
		TNT1 AAAA 0 A_CustomMissile ("BDExplosionparticlesSmall", 81, 0, random (0, 180), 2, random (40, 90))
		TNT1 A 0 A_PlaySound ("DSBOTTLE")
		TNT1 AAAAA 0 A_CustomMissile("GlassPart",16,random(-3,3),random(0,360),2,random(40,70))
		TNT1 A 0 A_SpawnItem("ExplosionSimpleSmokeColumn2", 0, 75)
		TLMP E -1
		stop
	}
}

Actor TechLamp21 : TechLamp2 replaces TechLamp2
{
    damagefactor "Avoid", 0.0    damagefactor "Kick", 0.0	damagefactor "Melee", 0.0
    damagefactor "KillMe", 0.0 damagefactor "Trample", 0.0
	+SHOOTABLE
	+NOBLOOD
	+GHOST
	+RANDOMIZE
	health 15
	deathheight 60
	+FORCEYBILLBOARD
	Mass 65535
	states
	{
	Vanilla:
		TLP2 ABCD 2 BRIGHT
		Loop

	Spawn:
		TLP2 A 0
		MARN A 0 ACS_NamedExecuteAlways("BDCheckDecorations", 0, 0, 0, 0)//Check if advanced decorations are disabled.
		TNT1 A 1

	Stay:
		TLP2 AB 2 bright A_SpawnItemEx("LensFlareAlt", 0, 0, 55)
		TLP2 CD 2 bright A_SpawnItemEx("LensFlareAlt", 0, 0, 55)
		Loop

	Death:
		TLP2 E 1
		TNT1 AAAA 0 A_CustomMissile ("BDExplosionparticlesSmall", 51, 0, random (0, 180), 2, random (40, 90))
		TNT1 A 0 A_PlaySound ("DSBOTTLE")
		TNT1 AAAAA 0 A_CustomMissile("GlassPart",16,random(-3,3),random(0,360),2,random(40,70))
		TNT1 A 0 A_SpawnItem("ExplosionSimpleSmokeColumn2", 0, 51)
		TLP2 E -1
		stop
	}
}

Actor BreakingLamp
{
+NOINTERACTION
States
	{
		Spawn:
		TNT1 A 0
		//TNT1 A 0 A_SpawnItem("Spark_DownOnce")
		TNT1 A 0 A_PlaySound ("DSBOTTLE")
		TNT1 AAAAAAAAAA 0 A_CustomMissile("GlassPart",0,random(-3,3),random(0,360),2,random(40,70))
		TNT1 AAAAAAAAAA 0 A_CustomMissile("ExplosionParticleHeavy",0,random(-3,3),random(0,360),2,random(0,70))
		TNT1 AAAA 0 A_CustomMissile("PlasmaSmoke",0,random(-3,3),random(0,360),2,random(0,70))
		TNT1 A 0
		Stop
	}
}

Actor Column1 : Column replaces Column
{
    damagefactor "Avoid", 0.0    damagefactor "Kick", 0.0	damagefactor "Melee", 0.0
    damagefactor "KillMe", 0.0 damagefactor "Trample", 0.0
	+NOTARGET
	Tag "Lamppost Short"
	+SHOOTABLE
	Mass 65535
	+NOBLOOD
	+GHOST
	health 15
	deathheight 48
	Radius 8
	+FORCEYBILLBOARD
	+RANDOMIZE
	states
	{
	Vanilla:
		COLU AA 14 BRIGHT
		TNT1 A 0 A_JumpIfInventory("MarkForDeletion", 1, "Disappear")
		COLU A -1 BRIGHT
		Stop

	Spawn:
		COLU A 0
		TNT1 A 0 A_SpawnItemEx("EvidenceCheckerLightpost", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
		MARN A 0 ACS_NamedExecuteAlways("BDCheckDecorations", 0, 0, 0, 0)//Check if advanced decorations are disabled.
		COLU AA 14
		TNT1 A 0 A_JumpIfInventory("MarkForDeletion", 1, "Disappear")

	Stay:
		COLU AAAA 2 bright A_SpawnItem("YellowLensFlareAltLong",0,44)
		Loop

	Death:
		COLU B 1
		TNT1 AAAA 0 A_CustomMissile ("BDExplosionparticlesSmall", 48, 0, random (0, 180), 2, random (40, 90))
		TNT1 A 0 A_PlaySound ("DSBOTTLE")
		TNT1 AAAAA 0 A_CustomMissile("GlassPart",16,random(-3,3),random(0,360),2,random(40,70))
		TNT1 A 0 A_SpawnItem("ExplosionSimpleSmokeColumn2", 0, 48)
		COLU B -1
		stop

	Disappear:
		TNT1 A 2 Thing_Remove(0)
		Stop
	}
}