ACTOR EvilMarineShield : Rifle
{
	Weapon.AmmoUse1 0
	Weapon.AmmoGive1 0
	Weapon.AmmoUse2 0
	Weapon.AmmoGive2 0
	Weapon.AmmoType1 "BDPistolAmmo"
	Weapon.AmmoType2 "MeatAmmo"
	Weapon.SelectionOrder 9999
	+WEAPON.CHEATNOTWEAPON
	+WEAPON.NO_AUTO_SWITCH
	States
	{
	Ready:
		MSHG A 2 A_WeaponReady
		TNT1 A 0 A_JumpIfInventory("MeatAmmo", 100, "Destroy")
		TNT1 A 0 A_SpawnItemEx("MeatShield", 16, -11, 0, 0)
        Loop

	Select:
		TNT1 A 0 A_Giveinventory("GoSpecial",1)
	    TNT1 A 0 A_TakeInventory("MeatAmmo", 100)
		TNT1 A 0 A_Raise
		MSHG A 1 offset(0,40)
		MSHG A 1 offset(0,48)
		Goto LoadBullets

	LoadBullets:
		TNT1 A 0 A_JumpIfInventory("BDPistolAmmo",16,"Ready")
		TNT1 A 0 A_JumpIfInventory("Clip1",1,3)
		Goto Ready
        TNT1 AAAAAA 0
		TNT1 A 0 A_Giveinventory("BDPistolAmmo",1)
		TNT1 A 0 A_Giveinventory("BDDualPistolAmmo",1)
		TNT1 A 0 A_Takeinventory("Clip1",1)
		Goto LoadBullets

	Fire:
	    TNT1 A 0
        TNT1 A 0 A_JumpIfInventory("BDPistolAmmo", 1, 1)
		Goto AltFire
		TNT1 A 0 A_FireCustomMissile("DistantFireSoundPistol", random(-1,1), 0, 0, -12, 0, random(-1,1))
		TNT1 A 0 A_PlaySound("pfire")
		TNT1 A 0 A_AlertMonsters
		TNT1 A 0 A_SpawnItemEx("PlayerMuzzle1",32,-4,28)
		MSHF A 2 BRIGHT A_FireBullets (1.8, 1.4, -1, 14, "WeakPuff", FBF_NORANDOM)
		TNT1 A 0 A_SpawnItemEx("MeatShield", 16, -11, 0, 0)
		TNT1 A 0 A_ZoomFactor(0.99)
        TNT1 A 0 A_FireCustomMissile("DecorativeTracer",random(-1,1),0,8,0,0,random(-1,1))
		PI2G A 0 A_Takeinventory("BDPistolAmmo",1)
		PI2G A 0 A_Takeinventory("BDDualPistolAmmo",1)
		PI2G A 0 A_FireCustomMissile("PistolCaseSpawn",5,0,16,-4)
		MSHF B 2
		TNT1 A 0 A_ZoomFactor(1.0)
		TNT1 A 0 A_SpawnItemEx("MeatShield", 16, -11, 0, 0)
		MSHF C 2
		TNT1 A 0 A_SpawnItemEx("MeatShield", 16, -11, 0, 0)
		MSHG A 1
		TNT1 A 0 A_Refire
		Goto Ready

	Deselect:
    AltFire:
		GRZ5 D 1 offset(-4, 32)
		GRZ5 D 1 offset(-9, 33)
		GRZ5 D 1 offset(-16, 34)
		GRZ5 D 2 offset(-24, 35)
		GRZ5 D 3 offset(-36, 48)
		GRZ5 D 1 offset(-24, 35)
		GRZ5 B 1 offset(-16, 34)
		GRZ5 B 1 offset(-9, 33)
		GRZ5 B 1 offset(-1, 32)
        TNT1 A 0 A_PlaySound("skeleton/swing")
		TNT1 A 0 A_FireCustomMissile("ThrowedEvilMarine", 0, 0, 0, 0)
		TNT1 A 0 A_TakeInventory("GoSpecial",1)
        TNT1 A 0 A_TakeInventory("GotMeatShield", 1)
        TNT1 A 0 A_TakeInventory("HasEvilMarineShield",1)
        TNT1 A 0 A_Giveinventory("Punching",1)
        THEF BCD 4
        TNT1 A 0 A_TakeInventory("EvilMarineShield",1)
        Stop

 	Spawn:
		8876 A -1
		Stop

	Destroy:
	    TNT1 A 0
		TNT1 A 0 A_SpawnItem("ZombiemanHeadExplode", 0, 50)
		TNT1 A 12
        TNT1 A 0 A_PlaySound("skeleton/swing")
		TNT1 A 0 A_FireCustomMissile("ThrowedEvilMarine", 0, 0, 0, 0)
		TNT1 A 0 A_TakeInventory("GoSpecial",1)
        TNT1 A 0 A_TakeInventory("GotMeatShield", 1)
        TNT1 A 0 A_TakeInventory("HasEvilMarineShield",1)
        TNT1 A 0 A_Giveinventory("Punching",1)
        THEF BCD 4
        TNT1 A 0 A_TakeInventory("EvilMarineShield",1)
        Stop
	}
}

ACTOR ThrowedEvilMarine: ThrowedZman
{
Translation "112:127=[64,64,64]:[0,0,0]"
	States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_Playsound("BIGSCRE", 1)
	Flying:
        X725 H 3
		TNT1 A 0 A_ChangeFlag("THRUGHOST", 0)
		X725 GFEDCBA 3
		Loop

	XDeath:
    Death:
		TNT1 A 0
		TNT1 A 0 A_StopSound(1)
		TNT1 A 0 A_NoBlocking
		TNT1 A 0 A_CheckCeiling("HitCeil")
		TNT1 A 0 A_JumpIfHealthLower(-40, "Death.Gibs")
		TNT1 A 0 A_JumpIfHealthLower(1, "Death.Chaingun")
		X725 A 2
		NULL AA 0 A_CustomMissile ("XDeath1", 0, 0, random (0, 360), 2, random (0, 160))
	    TNT1 A 0 A_SpawnItem("MuchBlood2")
		NULL A 0 A_CustomMissile ("ThrowedEvilMarineRicochet", 0, 0, 0, 2, 38)
		Stop

	HitCeil:
		TNT1 A 0
		TNT1 A 0 A_SpawnItem("MuchBlood2")
		NULL A 0 A_CustomMissile ("ThrowedEvilMarineRicochet", 0, 0, 0, 2, -5)
		Stop

	Crashing:
		TNT1 A 0 A_StopSound(1)
		TNT1 A 0 A_NoBlocking
		TNT1 A 0 A_SpawnItem("MuchBlood2")
		NULL AA 0 A_CustomMissile ("XDeath1", 0, 0, random (0, 360), 2, random (0, 160))
		TNT1 A 0 A_SpawnItemEx("ADoomedSpaceMarine", 0, 0, 0, 0, 0, 0, 0, SXF_TRANSFERTRANSLATION)
		TNT1 A 3
		Stop

	Death.Melee:
	Death.Fatality:
	Death.ExtremePunches:
	Death.Kick:
		TNT1 A 0 A_StopSound(1)
		TNT1 A 0 A_NoBlocking
		NULL A 0 A_CustomMissile ("ThrowedEvilMarineRicochet", 0, 0, 180, 2, 32)
		Stop

	Death.Shotgun:
	Death.Gibs:
	Death.Explosive:
	Death.Chaingun:
		TNT1 A 0
		TNT1 A 0 A_SpawnItem("MarineXDeath")
		Stop
	}
}

ACTOR ThrowedEvilMarineRicochet: ThrowedEvilMarine
{
    +BOUNCEONWALLS
	+THRUGHOST
	+BOUNCEONACTORS
	WallBounceFactor 0.6
	Speed 10
	States
	{
	Spawn:
        X725 H 2
		TNT1 A 0 A_ChangeFlag("THRUGHOST", 0)
		X725 GFEDCBA 2
		Loop
    Death:
	XDeath:
		TNT1 A 0
		TNT1 A 0 A_StopSound(1)
		TNT1 A 0 A_NoBlocking
		TNT1 A 0 A_JumpIfHealthLower(-40, "Death.Gibs")
		TNT1 A 0 A_JumpIfHealthLower(1, "Death.Chaingun")
	Goto Crashing
	}
}

ACTOR ExtremePunchedEvilMarine: ThrowedEvilMarine
{
	Speed 30
	+THRUGHOST
	States
	{
	Spawn:
        PLAY HH 2 A_CustomMissile ("Brutal_FlyingBloodTrail", 0, 0, random (0, 360), 2, random (0, 90))
		TNT1 A 0 A_ChangeFlag("THRUGHOST", 0)
		Loop
    XDeath:
    Death:
		TNT1 A 0
		TNT1 A 0 A_CheckFloor("Floor")
		TNT1 A 0 A_CheckCeiling("Floor")
		TNT1 A 0 A_SetAngle(angle-180)
		TNT1 A 0 A_Stop
		TNT1 A 0 A_ChangeFlag("LOWGRAVITY", 1)
		TNT1 AA 0 A_CustomMissile ("XDeath2", 32, 0, random (170, 190), 2, random (0, 0))
		TNT1 AA 0 A_CustomMissile ("XDeath3", 32, 0, random (170, 190), 2, random (0, 0))
		TNT1 A 0 A_SpawnItem("Muchblood2", 0, 40)

	    TNT1 AAA 0 A_CustomMissile ("Guts", 32, 0, random (150, 210), 2, random (0, 40))
		TNT1 AA 0 A_CustomMissile ("XDeathArm1", 32, 0, random (170, 190), 2, random (0, 40))
		//TNT1 A 0 A_CustomMissile ("XDeathZombiemanHead", 32, 0, random (170, 190), 2, random (0, 40))
        NULL AAAA 0 A_CustomMissile ("Brains1", 50, 0, random (0, 360), 2, random (0, 160))
		NULL A 0 A_CustomMissile ("Brains2", 50, 0, random (0, 360), 2, random (0, 160))
		NULL A 0 A_CustomMissile ("Brains3", 50, 0, random (0, 360), 2, random (0, 160))
		NULL A 0 A_CustomMissile ("Brains4", 50, 0, random (0, 360), 2, random (0, 160))
		NULL A 0 A_CustomMissile ("Brains5", 50, 0, random (0, 360), 2, random (0, 160))
		NULL AAAA 0 A_CustomMissile ("SmallBrainPiece", random (45, 55), random (5, -5), random (170, 190), 2, random (0, 40))
		NULL AAAA 0 A_CustomMissile ("SmallBrainPiece", 50, 0, random (0, 360), 2, random (0, 160))
		NULL AA 0 A_CustomMissile ("SuperWallRedBlood", 46, 0, random (170, 190), 2, random (0, 40))
        NULL AAAAAAAAAAA 0 A_CustomMissile ("BrainBlood", 50, 0, random (0, 360), 2, random (0, 160))
	    TNT1 A 0 A_XScream
		TNT1 A 0 A_NoBlocking
        XPL2 GGGG 6
		TNT1 A 0 A_ChangeFlag("LOWGRAVITY", 0)
		XPL2 GG 6
		TNT1 A 0 A_SpawnItem ("GrowingBloodPool")
		XPL2 G 0
		TNT1 A 0 A_GiveToTarget("SoulAmmo", 10)
		TNT1 A 0 A_SpawnItemEx("PlayerJustGotCutInHalf", 0, 0, 0, 0, 0, 0, 0, SXF_TRANSFERTRANSLATION)
		TNT1 A -1
        Stop

	Floor:
		TNT1 AA 0 A_CustomMissile ("XDeath1", 35, 0, random (0, 360), 2, random (0, 160))
		TNT1 A 0 A_Recoil(-30)
		PLAY HIJKL 3 A_CustomMissile ("Brutal_LiquidBlood3", 15, 0, random (0, 360), 2, random (0, 40))
		PLAY MN 3 A_JumpIf((MomY == 0), "DSFStop")
		Goto DSFStop+1

	DSFStop:
		TNT1 A 0 A_SpawnItem("Ploft3")
		TNT1 A 0 A_Stop
		TNT1 A 0 A_SpawnItem ("GrowingBloodPool")
		TNT1 A 0 A_CustomMissile ("SuperWallRedBlood", 2, 0, random (170, 190), 2, random (0, 0))
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("ADoomedSpaceMarine", 0, 0, 0, 0, 0, 0, 0, SXF_TRANSFERTRANSLATION)
		TNT1 A 0 A_GiveToTarget("SoulAmmo", 10)
		TNT1 A -1
		Stop
	}
}