ACTOR BFG10K2 : "BFG10K " replaces "BFG10K " 
{
  Weapon.SisterWeapon "PoweredBFG10k"
  Tag "BFG10k"
}

ACTOR PoweredBFG10k : BFG10K2
{
  Weapon.AmmoUse 8
  Weapon.SisterWeapon "BFG10K2"
  +WEAPON.POWERED_UP
  States
  {
  Ready:
	TNT1 A 0 A_JumpIfNoAmmo("Ready2")
	TNT1 A 0 A_PlayWeaponSound("weapons/bfg15kidle")
	EG2G AAABBBCCCDDD 1 A_WeaponReady
	Loop
  Ready2:
	TNT1 A 0 A_JumpIfInventory("NewCell",8,"Ready")
	EGE2 A 1 A_WeaponReady
	Loop
  Select:
	TNT1 A 0 A_JumpIfNoAmmo("Select2")
	TNT1 A 0 A_Playsound("weapons/pickup15k")
  SelectLoop:
	EG2G A 1 A_Raise
	Loop
  Select2:
	TNT1 A 0 A_PlayWeaponSound("weapons/pickup15k")
  Select2Loop:
	EGE2 A 1 A_Raise
	Loop
  Deselect:
	TNT1 A 0 A_TakeInventory("HandGrenadeAction",1)
	TNT1 A 0 A_TakeInventory("MineAction",1)
	TNT1 A 0 A_TakeInventory("RailgunAction",1)
	TNT1 A 0 A_JumpIfNoAmmo("Deselect2")
	TNT1 A 0 A_PlayWeaponSound("weapons/weapondown")
  DeselectLoop:
	EG2G A 1 A_Lower
	Loop
  Deselect2:
	TNT1 A 0 A_PlayWeaponSound("weapons/weapondown")
  Deselect2Loop:
	EGE2 A 1 A_Lower
	Loop
  Fire:
	EG2G E 25 A_PlayWeaponSound("weapons/charge15k")
	EG2G F 4
	EG2G GHIJ 1
	Goto Hold
  Hold:
	TNT1 A 0 Bright
	EG2E A 1 Bright A_GunFlash
	EG2G K 1 Bright
	//TNT1 A 0 A_PlaySound("weapons/bfg15kfire")
	TNT1 A 0 Radius_Quake(6,3,0,1,0)
	EG2E B 1 Bright A_FireCustomMissile("EmpoweredBFG15KBall",Random(100,-100)/100.00,1,0,0,0,Random(100,-100)/100.00)
	EG2G LMNO 1
	TNT1 A 0 A_ReFire
	EG2G O 35 A_PlaySound("weapons/bfg15kcooldown") 
	Goto Ready
	}
}

ACTOR EmpoweredBFG15KBall : BFG15KBall
{
  Speed 50
  +SEEKERMISSILE
  States
  {
  Spawn:
    EPS1 AB 2 Bright A_SpawnItemEx("PoweredBFGTrailparticle",Random(-8,8),Random(-8,8),Random(-8,8),Random(-1,1),Random(-1,1),Random(-1,1),Random(-20,20),128)
	TNT1 A 0 A_SeekerMissile(3,3,SMF_LOOK)
    Loop
  Death:
	TNT1 A 0
    TNT1 A 0 A_SpawnItemEx("PoweredBFGShockwave", 0, 0, 0, 0, 0, 0, 0, 128)
	TNT1 A 0 A_SpawnItemEx("GreenParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
	TNT1 AA 0 A_CustomMissile("KaboomBlue", 0, 0, random(0,360), 2, random(0,360))      
    EPE1 A 4 Bright A_Explode	
    EPE1 BCDEF 4 Bright
    Stop
    }
}