ACTOR PlaguedBruiserDemon : BruiserDemon
{ 
  Health 1700
  PainChance 50
  BloodColor "Purple"
  DropItem "ExtraArmor" 65
  DropItem "BossLifeEssence" 210
  DropItem "BossArmorBonusMax" 210
  MeleeDamage 10
  Scale 1.1
  +BRIGHT
  +NOTARGET
  +MISSILEMORE
  Obituary "%o was intoxicated by a Plagued Bruiser Demon."
  HitObituary "%o was infected by a Plagued Bruiser Demon."
  Tag "\c[s9]Plagued Bruiser Demon\c-"
  States
  {
  Spawn:
	PLBB AA 7 A_Look
	PLBI AA 7 A_Look
	Loop
  See:
	PLBB AABB 3 A_Chase
	TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
	PLBB CCDD 3 A_Chase
	TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
	TNT1 A 0 A_Jump(70,"Rush")
	Loop
  Rush:
	TNT1 A 0 A_UnHideThing
	TNT1 A 0 A_SetTranslucent(1)
	TNT1 A 0 A_SpawnItemEx("PlagueGhostA",0,0,0,0,0,0,0,128)
	PLBB A 1 A_Chase
	TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
	TNT1 A 0 A_SpawnItemEx("PlagueGhostA",0,0,0,0,0,0,0,128)
	PLBB A 1 A_Chase
	TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
	TNT1 A 0 A_SpawnItemEx("PlagueGhostB",0,0,0,0,0,0,0,128)
	PLBB B 1 A_Chase
	TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
	TNT1 A 0 A_SpawnItemEx("PlagueGhostB",0,0,0,0,0,0,0,128)
	PLBB B 1 A_Chase
	TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
	TNT1 A 0 A_SpawnItemEx("PlagueGhostC",0,0,0,0,0,0,0,128)
	PLBB C 1 A_Chase
	TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
	TNT1 A 0 A_SpawnItemEx("PlagueGhostC",0,0,0,0,0,0,0,128)
	PLBB C 1 A_Chase
	TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
	TNT1 A 0 A_SpawnItemEx("PlagueGhostD",0,0,0,0,0,0,0,128)
	PLBB D 1 A_Chase
	TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
	TNT1 A 0 A_SpawnItemEx("PlagueGhostD",0,0,0,0,0,0,0,128)
	PLBB D 1 A_Chase
	PLBB D 1 A_Chase
	TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
	TNT1 A 0 A_Jump(84,"See")
	Loop
  Missile:
	TNT1 A 0 A_Jump(128,"LargeBall","Comets","LargeComet")
	TNT1 A 0 A_Jump(64,"LargeComets","SuperFloorFire")
  Normal:
	PLBB EF 6 A_FaceTarget
	PLBB G 1 A_CustomMissile("PlagueBall",32,0,0)
	TNT1 A 0 A_CustomMissile("PlagueBall",32,0,-5)
	PLBB G 5 A_CustomMissile("PlagueBall",32,0,5)
	PLBB HI 6 A_FaceTarget	
	PLBB J 1 A_CustomMissile("PlagueBall",32,0,0)
	TNT1 A 0 A_CustomMissile("PlagueBall",32,0,-5)
	PLBB J 5 A_CustomMissile("PlagueBall",32,0,5)
	TNT1 A 0 A_Jump(100,"Comets")
	Goto See
  LargeBall:
	PLBB EF 6 A_FaceTarget
	PLBB G 5 A_CustomMissile("PlagueBallBig",32,0,0)
	PLBB HI 6 A_FaceTarget
	PLBB J 5 A_CustomMissile("PlagueBallBig",32,0,0)
	PLBB EF 6 A_FaceTarget
	PLBB G 5 A_CustomMissile("PlagueBallBig",32,0,0)
	TNT1 A 0 A_Jump(100,"Comets","LargeComet")
	Goto See
  Comets:
	PLBB KL 7 A_FaceTarget  
	PLBB M 2 A_CustomMissile("PlagueComet",32,0,0)
	TNT1 A 0 A_CustomMissile("PlagueComet",32,0,10)
	PLBB M 4 A_CustomMissile("PlagueComet",32,0,-10)
	TNT1 A 0 A_Jump(128,"See","Normal")
	PLBB LKL 7 A_FaceTarget  
	PLBB M 2 A_CustomMissile("PlagueComet",32,0,0)
	TNT1 A 0 A_CustomMissile("PlagueComet",32,0,10)
	PLBB M 4 A_CustomMissile("PlagueComet",32,0,-10)
	Goto See
  LargeComet:
	PLBB KL 10 A_FaceTarget  
	PLBB M 10 A_CustomMissile("PlagueCometLarge",32,0,0)
	TNT1 A 0 A_Jump(128,"See","LargeBall")
	PLBB LKL 10 A_FaceTarget  
	PLBB M 10 A_CustomMissile("PlagueCometLarge",32,0,0)
	Goto See
  LargeComets:
    TNT1 A 0 A_ChangeFlag("NOPAIN",1)
	TNT1 A 0 A_PlaySound("superbaron/scream")
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	PLBB L 12
	PLBB M 2 A_CustomMissile("PlagueCometLarge",32,0,0)
	TNT1 A 0 A_CustomMissile("PlagueCometLarge",32,0,12)
	PLBB M 16 A_CustomMissile("PlagueCometLarge",32,0,-12)
	TNT1 A 0 A_ChangeFlag("NOPAIN",0)
	TNT1 A 0 A_Jump(100,"SuperFloorFire")
	Goto See
  SuperFloorFire:
    TNT1 A 0 A_ChangeFlag("NOPAIN",1)
	TNT1 A 0 A_PlaySound("superbaron/scream")
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	TNT1 A 0 A_FaceTarget
	PLBB K 6 A_SpawnItemEx("PlagueAttackFireSpawner")  
	PLBB KL 10 Bright A_FaceTarget 	
	PLBB M 0 A_Custommissile("PBruiserFireSpawner",16,0,0)
	PLBB M 0 A_Custommissile("PBruiserFireSpawner",16,0,8)
	PLBB M 0 A_Custommissile("PBruiserFireSpawner",16,0,-8)
	PLBB M 0 A_Custommissile("PBruiserFireSpawner",16,0,16)
	PLBB M 0 A_Custommissile("PBruiserFireSpawner",16,0,-16)
	PLBB M 8 Bright A_FaceTarget
	TNT1 A 0 A_ChangeFlag("NOPAIN",0)
	Goto See
  Melee:
	PLBB EF 8 A_FaceTarget
	PLBB G 7 A_MeleeAttack
	Goto See
  Pain:
	//TNT1 A 0 A_Jump(61,"MissilePain")		it's time to stop
	PLBB N 4 A_Pain
	TNT1 A 0 A_Jump(80,"Missile") //do this instead please
	Goto See
  Death: 
	PLBD A 7
	PLBD B 6 A_Scream 
	PLBD D 5 A_Fall 
	TNT1 AAAA 0 A_CustomMissile("SmokeFX", Random(30,60), 0, random(0,360), 2, random(0,360))  
	TNT1 AAAAAAAAAAAAAAAAAAAA 0 A_SpawnItemEx("PlagueBruiserPoisonCloudLarge",0,0,20,Random(8,-8),Random(8,-8),Random(6,-6))
	PLBD EFGHIJKL 4 A_SpawnItemEx("PlagueDeathParticleSpawner", Random(10,-10), Random(10,-10), Random(30,60), 0, 0, 0, 0, 128)  
	TNT1 A 0 A_ChangeFlag("BRIGHT",0)
	PLBD MNOP 4
	PLBD QRST 3
	PLBD V 3 A_SpawnItem("BodyCrash")
	PLBD W -1 A_KillMaster
	Stop 
  Raise:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
	PLBD VUTSRQP 2
	TNT1 A 0 A_ChangeFlag("BRIGHT",1)
	PLBD ONMLKJIHGFEDCBA 2
	Goto See
	}
}

ACTOR PBruiserFire : PyroFire
{
Obituary "%o was intoxicated by a Plagued Bruiser Demon."
States
{
Spawn:
	PLFB AB 2 Bright
	TNT1 A 0 A_SpawnItemEx("PurpleParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
	TNT1 AAAA 0 A_SpawnItemEx("PlagueBruiserPoisonCloudMedium",0,0,4,random(-2,2),random(-2,2),random(0,6))  
    PLFB C 2 Bright A_Explode(42,106,0)
    PLFB DEFGHIJKLMNOPQRST 2 Bright
    Stop       
	}
}

ACTOR PBruiserFireSpawner : PyroFireSpawner
{
Obituary "%o was intoxicated by a Plagued Bruiser Demon."
States
{
Spawn: 
	TNT1 AAAAAA 1 Bright A_Weave(3,0,3,0)
	TNT1 A 0 A_PlaySound("weapons/rocklx")
	TNT1 A 1 Bright A_SpawnItemEx("PBruiserFire",0,0,0,0,0,0,0,SXF_TRANSFERPOINTERS)
    Loop
Death:  
    TNT1 A 1
    Stop
	}
}

ACTOR PlagueAttackFireSpawner : RedParticleSpawner
{
  ReactionTime 6
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
	TNT1 A 0 A_SpawnItemEx("PHellionSmoke",0,36,59,frandom(-1,1),frandom(-1,1),frandom(0,4))
	TNT1 A 0 A_SpawnItemEx("PHellionSmoke",0,-36,59,frandom(-1,1),frandom(-1,1),frandom(0,4))
	TNT1 A 1 A_CountDown
	Stop
  Death:
	Stop
	}
}

ACTOR PlagueComet : Comet
{
//ExplosionDamage 64		Oh my god why is this shit still used
//ExplosionRadius 102
//MissileType "Daedalus why are you still using a_missileattack"
  DECAL Scorch
  States
  {
  Spawn:
	PNCM AAABBBCCC 1 Bright A_SpawnItemEx("PlagueCometTail")
	Loop
  Death:
	TNT1 A 0
	TNT1 A 0 A_Explode(64,102)
	TNT1 A 0 A_SetTranslucent(0.75,1)
	TNT1 A 0 A_SpawnItemEx("PurpleParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
	PNCM D 3 Bright A_SpawnItemEx("PlagueCometDeathGlow",0,0,0,0,0,0,0,128,0)
	TNT1 AAAAA 0 A_SpawnItemEx("PlagueBruiserPoisonCloudMedium",0,0,4,random(-6,6),random(-6,6),random(-6,6))  
	PNCM E 3 Bright A_SpawnItemEx("PlagueCometDeath",0,0,0,0,0,0,0,128,0)
	Stop
	}
}

ACTOR PlagueCometTail : CometTail
{
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
	PLUR ABCDEFGHI 1 Bright
	Stop
	}
}

ACTOR PlagueCometDeath : CometDeath
{
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 AAA 0 A_CustomMissile("PlagueKaboom3", 0, 0, random(0,360), 2, random(0,360))
	TNT1 AAA 0 A_CustomMissile("SmokeFX2", 0, 0, random(0,360), 2, random(0,360))
	PNCM FGHI 3 Bright A_FadeOut(0.1)
	Stop
	}
}

ACTOR PlagueCometDeathGlow : CometDeathGlow
{
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
	PLUR ABCDEFGHI 3 Bright
	Stop
	}
}

ACTOR PlagueCometLarge : PlagueComet
{
  Scale 1.3
  States
  {
  Spawn:
	PNCM AAABBBCCC 1 Bright A_SpawnItemEx("PlagueCometTailLarge")
	Loop
  Death:
	TNT1 A 0
	TNT1 A 0 A_Explode(130,200)
	TNT1 A 0 A_SetTranslucent(0.75,1)
	TNT1 AA 0 A_SpawnItemEx("PurpleParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
	PNCM D 3 Bright A_SpawnItemEx("PlagueCometDeathGlowLarge",0,0,0,0,0,0,0,128,0)
	TNT1 AAAAAAAA 0 A_SpawnItemEx("PlagueBruiserPoisonCloudLarge",0,0,4,random(-3,3),random(-3,3),random(-3,3))  
	PNCM E 3 Bright A_SpawnItemEx("PlagueCometDeathLarge",0,0,0,0,0,0,0,128,0)
	Stop
	}
}

ACTOR PlagueCometTailLarge : PlagueCometTail { Scale 1.65 }

ACTOR PlagueCometDeathLarge : CometDeath
{
  Scale 1.5
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 AAA 0 A_CustomMissile("PlagueKaboom", 0, 0, random(0,360), 2, random(0,360))
	TNT1 AAA 0 A_CustomMissile("SmokeFX3", 0, 0, random(0,360), 2, random(0,360))
	PNCM FGHI 3 Bright A_FadeOut(0.1)
	Stop
	}
}

ACTOR PlagueCometDeathGlowLarge : PlagueCometDeathGlow { Scale 2.6 }

ACTOR PlagueBall : BBall
{
  Speed 20
  FastSpeed 25
  Damage 8
  DECAL DoomImpScorch
  States
  {
  Spawn:
	PBBA AB 1 Bright A_SpawnItemEx("PlagueBallTrail")
	Loop
  Death:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("PurpleParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
	TNT1 AAA 0 A_CustomMissile("PlagueKaboom6", 0, 0, random(0,360), 2, random(0,360))
	TNT1 AAA 0 A_CustomMissile("SmokeFX4", 0, 0, random(0,360), 2, random(0,360))	
	TNT1 AAAAA 0 A_SpawnItemEx("PlagueBruiserPoisonCloudSmall",0,0,4,random(-2,2),random(-2,2),random(-2,2))  
	PBBA CDEFGHI 3 Bright
	Stop
    }
}

ACTOR PlagueBallTrail : BBallTrail
{
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
	TNT1 A 1
    PBBA AB 1 A_FadeOut(0.25)
    Goto Spawn+3
    }
}

ACTOR PlagueBallBig : BBall2
{
  Speed 25
  FastSpeed 32
  Damage 11
  States
  {
  Spawn: 
    PBB2 AB 2 Bright A_SpawnItemEx("PlagueBallBigTrail")
    Loop
  Death:
	TNT1 A 0
    TNT1 A 0 A_SpawnItemEx("PurpleParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
	TNT1 AAA 0 A_CustomMissile("PlagueKaboom6", 0, 0, random(0,360), 2, random(0,360))
	TNT1 AAA 0 A_CustomMissile("SmokeFX4", 0, 0, random(0,360), 2, random(0,360))	
	TNT1 AAAA 0 A_SpawnItemEx("PlagueBruiserPoisonCloudMedium",0,0,4,random(-4,4),random(-4,4),random(-4,4))  
    PBB2 KLMNOPQRSTUVWX 3 Bright
    Stop
  }
}

ACTOR PlagueBallBigTrail : BruiserBallTrail
{
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
    PBB2 CDEFGHIJ 3 Bright A_FadeOut
    Stop       
  }
}

ACTOR PlagueBruiserPoisonCloudSmall
{ 
  Radius 2
  Height 2
  RenderStyle Add
  Scale 0.5
  DamageType "NobleComet"
  +FORCERADIUSDMG
  +BLOODLESSIMPACT
  +RIPPER
  +THRUACTORS
  +DONTSPLASH
  +NOGRAVITY
  +NODAMAGETHRUST
  +NOTELEPORT
  +SKYEXPLODE
  +FORCEXYBILLBOARD
  States 
  { 
  Spawn: 
	PRPS ABCDE 3 A_Explode(1,38)
  Death:
	PRPS CCBBAA 1 A_FadeOut(0.15)
	Stop  
	} 
}

ACTOR PlagueBruiserPoisonCloudMedium : PlagueBruiserPoisonCloudSmall
{ 
  Scale 0.7
  States 
  { 
  Spawn: 
	PRPS ABCDEFGDEF 3 A_Explode(2,68)
  Death:
	PRPS CCBBAA 1 A_FadeOut(0.15)
	Stop  
	} 
}

ACTOR PlagueBruiserPoisonCloudLarge : PlagueBruiserPoisonCloudSmall
{ 
  Scale 1.0
  States 
  { 
  Spawn: 
	PRPS ABCDEFGDEFDEFG 3 A_Explode(2,88)
  Death:
	PRPS CCBBAA 1 A_FadeOut(0.15)
	Stop  
	} 
}

ACTOR PlagueKaboom : Kaboom
{
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
	TNT1 A 0 A_PlaySound("weapons/rocklx")
	PLXP AABBCDEFGHIJKLM 1 Bright A_FadeOut(0.05)
	Stop
	}
}

ACTOR PlagueKaboom3 : Kaboom3
{
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
	PLXP AABBCDEFGHIJKLM 1 Bright A_FadeOut(0.05)
	Stop
	}
}

ACTOR PlagueKaboom6 : Kaboom6
{
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
	PLXP AABBCDEFGHIJKLM 1 Bright A_FadeOut(0.05)
	Stop
	}
}

ACTOR PLEPSP1 : EnergyProjectileSparkPurple { Scale 0.06 +NOGRAVITY }
ACTOR PLEPSP2 : EnergyProjectileSparkPurple { Scale 0.05 +NOGRAVITY }
ACTOR PLEPSP3 : EnergyProjectileSparkPurple { Scale 0.04 +NOGRAVITY }
ACTOR PLEPSP4 : EnergyProjectileSparkPurple { Scale 0.03 +NOGRAVITY }
ACTOR PLEPSP5 : EnergyProjectileSparkPurple { Scale 0.02 +NOGRAVITY }
ACTOR PLEPSP6 : EnergyProjectileSparkPurple { Scale 0.01 +NOGRAVITY }
ACTOR PlagueDeathParticleSpawner : RedParticleSpawner
{
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
    TNT1 A 0 A_SpawnItemEx("PLEPSP1",0,0,0,Random(4,-4),Random(4,-4),Random(4,-4),0,128)
	TNT1 A 0 A_SpawnItemEx("PLEPSP2",0,0,0,Random(4,-4),Random(4,-4),Random(4,-4),0,128)
    TNT1 A 0 A_SpawnItemEx("PLEPSP3",0,0,0,Random(4,-4),Random(4,-4),Random(4,-4),0,128)
	TNT1 A 0 A_SpawnItemEx("PLEPSP4",0,0,0,Random(4,-4),Random(4,-4),Random(4,-4),0,128)
    TNT1 A 0 A_SpawnItemEx("PLEPSP5",0,0,0,Random(4,-4),Random(4,-4),Random(4,-4),0,128)
	TNT1 A 0 A_SpawnItemEx("PLEPSP6",0,0,0,Random(4,-4),Random(4,-4),Random(4,-4),0,128)
    TNT1 A 1
    Stop
  }
}

ACTOR PlagueGhostA
{
	Scale 1.1
	Radius 2
	Height 2
	Speed 0
	Alpha 0.7
	PROJECTILE
	RENDERSTYLE Translucent
	+CLIENTSIDEONLY
	+DONTSPLASH
	+THRUACTORS
States
{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
		TNT1 A 1
		PLBB A 2 A_FadeOut(0.10)
		Goto Spawn+1
	Toaster:
		TNT1 A 0
		Stop
}
}

ACTOR PlagueGhostB : PlagueGhostA
{
States
{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
		TNT1 A 1
		PLBB B 2 A_FadeOut(0.10)
		Goto Spawn+1
}
}

ACTOR PlagueGhostC : PlagueGhostA
{
States
{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
		TNT1 A 1
		PLBB C 2 A_FadeOut(0.10)
		Goto Spawn+1
}
}

ACTOR PlagueGhostD : PlagueGhostA
{
States
{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_JumpIf(CallAcs("LCAEffectCheck"),"Toaster")
		TNT1 A 1
		PLBB D 2 A_FadeOut(0.10)
		Goto Spawn+1
}
}