ACTOR InsanityCyberNoble : InfernalCyberNoble
{ 
  Health 2500
  PainChance 50
  Scale 1.2
  Damagefactor "Normal", 0.65
  Obituary "%o was given a nice, intimate introduction to an Insanity Cyber-Noble's cannon."
  HitObituary "%o was pummeled and bruised by an Insanity Cyber-Noble."
  DropItem "BossLifeEssence" 200 25
  DropItem "BossArmorBonusMax" 200 1
  DropItem "DemonAmmoBox" 128 200
  DropItem "BFG10K " 50 
  DropItem "NewCellPack" 128
  DropItem "NewShell" 256
  DropItem "NewShellBox" 128
  DropItem "Explosive Shotgun" 200
  DropItem "ExplosiveRailgun" 64
  Tag "\c[i7]Insanity Cyber-Noble\c-"
  States 
  { 
  Spawn: 
    SLAU A 7 A_Look
    Loop 
  See:
    TNT1 A 0 A_Jump(62,"Rush")
    SLAU AABB 3 A_Chase
    TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
    SLAU CCDD 3 A_Chase
    TNT1 A 0 A_Playsound("monster/bruwlk")
    Loop
  Rush:
	TNT1 A 0 A_SpawnItemEx("InsaneNobleGhostA",0,0,0,0,0,0,0,128)
	SLAU A 1 A_Chase
	TNT1 A 0 A_SpawnItemEx("InsaneNobleGhostA",0,0,0,0,0,0,0,128)
	SLAU A 1 A_Chase
	TNT1 A 0 A_SpawnItemEx("InsaneNobleGhostB",0,0,0,0,0,0,0,128)
	SLAU B 1 A_Chase
	TNT1 A 0 A_SpawnItemEx("InsaneNobleGhostB",0,0,0,0,0,0,0,128)
	SLAU B 1 A_Chase
    TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
	TNT1 A 0 A_SpawnItemEx("InsaneNobleGhostC",0,0,0,0,0,0,0,128)
	SLAU C 1 A_Chase
	TNT1 A 0 A_SpawnItemEx("InsaneNobleGhostC",0,0,0,0,0,0,0,128)
	SLAU C 1 A_Chase
	TNT1 A 0 A_SpawnItemEx("InsaneNobleGhostD",0,0,0,0,0,0,0,128)
	SLAU D 1 A_Chase
	TNT1 A 0 A_SpawnItemEx("InsaneNobleGhostD",0,0,0,0,0,0,0,128)
	SLAU D 1 A_Chase
    TNT1 A 0 A_Playsound("monster/bruwlk")
	TNT1 A 0 A_Jump(42,"See")	
	Loop
  Pause:
	SLAU E 10
	Goto See
  Pause2:
	SLAU A 10
	Goto See
  Melee:
    SLAU PQ 7 A_FaceTarget
    SLAU R 7 A_MeleeAttack
    Goto See
  Missile:
	TNT1 A 0 A_Jump(128,"Asg","laser","Ballspam","InfernalRockets")
    TNT1 A 0 A_jump(100,"BFG15k","Smallcomets","Spreadballs","SpreadSC")
    TNT1 A 0 A_jump(80,"Railgun","Bfg10k","comets","Spreadcomets","ExplosiveRailgun")
  Normal:
    SLAU E 12 A_FaceTarget
	SLAU E 3 A_FaceTarget
	TNT1 A 0 A_CustomMissile("InsaneNobleDemonTech",42,20,frandom(8,-8))
	SLAU F 2 Bright A_PlaySoundEx("weapons/demontechfire","Weapon")
	TNT1 A 0 A_Jump(20,"Pause")
	TNT1 A 0 A_SpidRefire
	Goto Normal+1
  InfernalRockets:
    SLAU EE 5 A_FaceTarget
    SLAU F 6 Bright A_CustomMissile("InfernalCyberNobleRocket",32,20,0,0)
    SLAU E 7 A_FaceTarget
    SLAU F 6 Bright A_CustomMissile("InfernalCyberNobleRocket",32,20,0,0)
    SLAU E 7 A_FaceTarget
    SLAU F 6 Bright A_CustomMissile("InfernalCyberNobleRocket",32,20,0,0)
    SLAU E 7 A_FaceTarget
    SLAU F 6 Bright A_CustomMissile("InfernalCyberNobleRocket",32,20,0,0)
    SLAU E 7 A_FaceTarget
    SLAU F 6 Bright A_CustomMissile("InfernalCyberNobleRocket",32,20,0,0)
    SLAU E 10
    Goto See
  Ballspam:
	SLAU PQ 7 A_FaceTarget 
	SLAU R 3 Bright A_CustomMissile("RIBall", 32, 0, 0)		
	SLAU PQ 4 A_Facetarget
	SLAU R 3 Bright A_CustomMissile("RIBall", 32, 0, 0)	
	SLAU PQ 4 A_Facetarget
	SLAU R 3 Bright A_CustomMissile("RIBall", 32, 0, 0)		
	SLAU R 4 A_Facetarget
	TNT1 A 0 A_Jump(20,"Pause2")
	TNT1 A 0 A_SpidRefire
	Goto Ballspam+1
  ASG:
	TNT1 A 0 A_JumpifCloser(200,"SSG")
	SLAU E 14 A_FaceTarget
	TNT1 A 0 A_PlaySound("weapons/ExplosiveSG/fire",7)
	TNT1 A 0 A_SpawnItemEx("OrangeShellCasing", 0, 12, 36, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
	TNT1 AAAAAA 0 Bright A_CustomMissile("CybernobleExplosiveTracer",42,20,Random(5,-5),0)
	SLAU F 4 Bright A_CustomBulletAttack(12,5,6,Random(5,7),"CyNoblePuff")
	SLAU E 8
    TNT1 A 0 A_Jump(128,"See")
    TNT1 A 0 A_SpidRefire
	Goto ASG+1
  SSG:
    SLAU E 8 A_FaceTarget
	SLAU E 12 A_FaceTarget
	TNT1 A 0 A_SpawnItemEx("ShellCasing", 0, 12, 36, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
	TNT1 AAAAAAAAA 0 Bright A_CustomMissile("CybernobleExplosiveTracer",42,20,Random(8,-8),0)
	TNT1 A 0 A_CustomBulletAttack(12, 8, 10, Random(1,4)*3, "CyNoblePuff")
	SLAU F 4 Bright A_PlaySoundEx("weapons/sshotf","Weapon")
    TNT1 A 0 A_Jump(128,"Pause")
	SLAU E 12
    TNT1 A 0 A_SpidRefire
	Goto Normal  
  Laser:
	TNT1 A 0 A_PlaySound("weapons/rgcharge")
    SLAU EEEE 5 A_FaceTarget
	TNT1 A 0 A_PlaySound("monsters/fusionfire")
    SLAU F 5 Bright A_CustomMissile("InsaneNoblelaser",42,20,0,0)
	SLAU E 4 a_facetarget
	TNT1 A 0 A_PlaySound("monsters/fusionfire")
	SLAU F 5 Bright A_CustomMissile("InsaneNoblelaser",42,20,0,0)
	SLAU E 4 a_facetarget
	TNT1 A 0 A_PlaySound("monsters/fusionfire")
	SLAU F 5 Bright A_CustomMissile("InsaneNoblelaser",42,20,0,0)
    SLAU E 20
	TNT1 A 0 A_Jump(64,"Railgun","BFG10K","Bfg15k")
	Goto See
  Smallcomets:
	SLAU PQ 7 A_FaceTarget 
	SLAU R 3 Bright A_CustomMissile("ArcradimusComet2", 32, 0, 0)		
	SLAU PQ 4 A_Facetarget
	SLAU R 3 Bright A_CustomMissile("ArcradimusComet2", 32, 0, 0)	
	SLAU PQ 4 A_Facetarget
	SLAU R 3 Bright A_CustomMissile("ArcradimusComet2", 32, 0, 0)		
	Goto See
  Spreadballs:
    SLAU PQ 8 A_FaceTarget
	SLAU R 1 Bright A_CustomMissile("RIBall", 32, 0, 0)		
	TNT1 A 0 A_CustomMissile("RIBall", 32, 0, 6)
	SLAU R 1 Bright A_CustomMissile("RIBall", 32, 0, -6)
	TNT1 A 0 A_CustomMissile("RIBall", 32, 0, 12)
	SLAU R 5 Bright A_CustomMissile("RIBall", 32, 0, -12)
	TNT1 A 0 A_jump(64,"SpreadSC","Comets","Spreadcomets")
	Goto See
  SpreadSC:
	SLAU PQ 8 A_FaceTarget
	SLAU R 1 Bright A_CustomMissile("ArcradimusComet2", 32, 0, 0)		
	TNT1 A 0 A_CustomMissile("RISeekerComet", 32, 0, 6)
	SLAU R 1 Bright A_CustomMissile("ArcradimusComet2", 32, 0, -6)
	TNT1 A 0 A_CustomMissile("RISeekerComet", 32, 0, 12)
	SLAU R 5 Bright A_CustomMissile("ArcradimusComet2", 32, 0, -12)
	TNT1 A 0 A_jump(64,"Comets","Spreadcomets")
	Goto See
  BFG10k:
	TNT1 A 0 A_PlayWeaponSound("weapons/charge15k")
    SLAU E 25 A_FaceTarget
	TNT1 A 0 A_PlaySound("weapons/bfg15kfire")
    SLAU F 4 Bright A_CustomMissile("Cy10K",42,20,0,0)
    SLAU E 8 A_FaceTarget
	TNT1 A 0 A_PlaySound("weapons/bfg15kfire")
    SLAU F 4 Bright A_CustomMissile("Cy10K",42,20,0,0)
    SLAU E 8 A_FaceTarget
	TNT1 A 0 A_PlaySound("weapons/bfg15kfire")
    SLAU F 4 Bright A_CustomMissile("Cy10K",42,20,0,0)
    SLAU E 8 A_FaceTarget
	TNT1 A 0 A_PlaySound("weapons/bfg15kfire")
    SLAU F 4 Bright A_CustomMissile("Cy10K",42,20,0,0)
    SLAU E 8 A_FaceTarget
	TNT1 A 0 A_PlaySound("weapons/bfg15kfire")
    SLAU F 4 Bright A_CustomMissile("Cy10K",42,20,0,0)
    SLAU E 10 A_PlaySound("weapons/bfg15kcooldown",CHAN_AUTO)
	TNT1 A 0 A_Jump(128,"railgun")
    Goto See
  BFG15k:
	TNT1 A 0 A_PlaySound("weapons/charge15k")
    SLAU E 18 A_FaceTarget
	SLAU E 6 A_FaceTarget
    SLAU F 4 Bright A_CustomMissile("Cybruiser15K",32,20,Random(4,-4))	
	SLAU E 4 A_FaceTarget
    SLAU F 4 Bright A_CustomMissile("Cybruiser15K",32,20,Random(4,-4))
	SLAU E 4 A_FaceTarget
    SLAU F 4 Bright A_CustomMissile("Cybruiser15K",32,20,Random(4,-4))
	SLAU E 4 A_FaceTarget
    SLAU F 4 Bright A_CustomMissile("Cybruiser15K",32,20,Random(4,-4))
	SLAU E 20 A_PlaySound("weapons/bfg15kcooldown",CHAN_AUTO)
	TNT1 A 0 A_Jump(128,"railgun")
	Goto See
  Railgun:
	TNT1 A 0 A_changeflag("Nopain",1)
	TNT1 A 0 A_PlaySound("weapons/rgcharge")
    SLAU EEEE 5 A_FaceTarget
	TNT1 A 0 A_PlaySound("railgunner/chargedshot")
    SLAU F 5 Bright A_CustomMissile("CydestroyerRail",42,20,0,0)
    SLAU E 20
	TNT1 A 0 A_changeflag("Nopain",0)
	Goto See
  Comets:
	SLAU PQ 8 A_FaceTarget 
	SLAU R 7 Bright A_CustomMissile("Comet", 32, 0, 0)		
	Goto see
  Spreadcomets:
	SLAU PQ 8 A_FaceTarget 
	SLAU R 3 Bright A_CustomMissile("Comet", 32, 0, 0)		
	TNT1 A 0 A_CustomMissile("Comet", 32, 0, 6)
	SLAU R 3 Bright A_CustomMissile("Comet", 32, 0, -6)
	Goto see
  ExplosiveRailgun:
	TNT1 A 0 A_PlaySound("ExplosiveRailgun/Charge")
	TNT1 A 0 A_PlaySound("InfernalCyberbaron/Attack",7)
    SLAU EE 20 A_FaceTarget
	TNT1 A 0 A_PlaySound("ExplosiveRailgun/Fire")
    TNT1 A 0 A_CustomMissile("NobleExplosiveRailgunImpact",32,20,0,0)
    SLAU F 5 Bright A_CustomRailgun(50,20,None,None,RGF_SILENT,1,0,"BruiserRailPuff",0,0,0,0,40,0,"ExplosiveRailgunTrail")
    SLAU EE 15 A_FaceTarget
	TNT1 A 0 A_Jump(128,"See","BFG10K")
	TNT1 A 0 A_PlaySound("ExplosiveRailgun/Fire")
    TNT1 A 0 A_CustomMissile("NobleExplosiveRailgunImpact",32,20,0,0)
    SLAU F 5 Bright A_CustomRailgun(50,20,None,None,RGF_SILENT,1,0,"BruiserRailPuff",0,0,0,0,40,0,"ExplosiveRailgunTrail")
    SLAU EE 15
	TNT1 A 0 A_Jump(64,"BFG10K")
	Goto See
  Pain: 
    SLAU G 4 A_Pain
    TNT1 A 0 A_Jump(87,"Missile")
    Goto See
  Death:
  Xdeath:
	SLAU G 10
    SLAU I 10 A_Scream
	TNT1 A 0 A_SpawnItemEx("GibbedGenerator")
	TNT1 AA 0 A_CustomMissile("SmokeFX2", 0, 0, random(0,360), 2, random(0,360))	
	SLAU JJJJ 2 Bright A_CustomMissile("Kaboom17", Random(10,50), 0, random(0,360), 2, random(0,360))
	SLAU KKKK 2 Bright A_CustomMissile("Kaboom17", Random(10,50), 0, random(0,360), 2, random(0,360))
	TNT1 A 0 A_SpawnItemEx("GibbedGenerator")
	TNT1 AA 0 A_CustomMissile("SmokeFX2", 0, 0, random(0,360), 2, random(0,360))	
	SLAU LLLL 2 Bright A_CustomMissile("Kaboom17", Random(10,50), 0, random(0,360), 2, random(0,360))
	TNT1 A 0 A_SpawnItemEx("GibbedGenerator")
	TNT1 AA 0 A_CustomMissile("SmokeFX2", 0, 0, random(0,360), 2, random(0,360))	
	SLAU MMMM 2 Bright A_CustomMissile("Kaboom17", Random(10,50), 0, random(0,360), 2, random(0,360))
	TNT1 A 0 A_SpawnItemEx("GibbedGenerator")
	TNT1 AAAA 0 A_CustomMissile("SmokeFX2", 0, 0, random(0,360), 2, random(0,360))
    SLAU N 4 Bright A_NoBlocking
    SLAU O 3
    SLAU O -1 A_KillMaster
    Stop
  Raise:
  	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
    SLAU N 5
	SLAU MLKJI 5
	Goto See
    } 
}

//Attacks
ACTOR InsaneNobleDemonTech : RedZDemonTechProjectile
{
DamageType "Noblecomet"
Speed 75
Damage 4
}

Actor InsaneNoblelaser : SpecOpsLaser
{
DamageType "Noblecomet"
Damage 15
}

ACTOR InsaneNobleGhostA
{
RENDERSTYLE Translucent
Alpha 0.75
Scale 1.15
+NOGRAVITY
+CLIENTSIDEONLY
+DONTSPLASH
+NOINTERACTION
+NOCLIP
States
{
Spawn:
    SLAU A 2 A_FadeOut(0.18)
    Loop	
    }
}

ACTOR InsaneNobleGhostB : InsaneNobleGhostA
{
States
{
Spawn:
    SLAU B 2 A_FadeOut(0.18)
    Loop
    }
}

ACTOR InsaneNobleGhostC : InsaneNobleGhostA
{
States
{
Spawn:
    SLAU C 2 A_FadeOut(0.18)
    Loop
    }
}

ACTOR InsaneNobleGhostD : InsaneNobleGhostA
{
States
{
Spawn:
    SLAU D 2 A_FadeOut(0.18)
    Loop
    }
}