ACTOR Revolver2 : BrutalWeapon
{
	Weapon.SelectionOrder 1300
	Weapon.AmmoUse1 0
	Weapon.AmmoUse2 0
	Weapon.AmmoGive1 0
	Weapon.AmmoGive2 0
	Weapon.AmmoType1 "Clip2"
	Weapon.AmmoType2 "RevolverAmmo"
	Inventory.PickupMessage "You got the Shotvolver! Say farewell to your wrists."
    Inventory.PickupSound "REVOFIRpump"
	Obituary "$OB_MPSHOTGUN"
    AttackSound "None"
    +WEAPON.NOALERT
    +WEAPON.NOAUTOAIM
	+WEAPON.NOAUTOFIRE
	+WEAPON.CHEATNOTWEAPON
	Scale 0.9
	Tag "Revolver"
	States
	{
		
    Spawn:
		REVP A -1
		Stop
    	
	Select:
		REVO A 0 A_Giveinventory("GoSpecial",1)
		REVO A 0 A_Takeinventory("FistsSelected",1)
		REVO A 0 A_Takeinventory("SawSelected",1)
		REVO A 0 A_Giveinventory("ShotgunSelected",1)
		REVO A 0 A_Takeinventory("SSGSelected",1)
		REVO A 0 A_Takeinventory("MinigunSelected",1)
		REVO A 0 A_Takeinventory("PlasmaGunSelected",1)
		REVO A 0 A_Takeinventory("RocketLauncherSelected",1)
		REVO A 0 A_Takeinventory("GrenadeLauncherSelected",1)
		REVO A 0 A_Takeinventory("BFGSelected",1)
		REVO A 0 A_Takeinventory("BFG10kSelected",1)
		REVO A 0 A_Takeinventory("RailGunSelected",1)
		REVO A 0 A_Takeinventory("SubMachineGunSelected",1)
		REVO A 0 A_Takeinventory("RevenantLauncherSelected",1)
		REVO A 0 A_Takeinventory("LostSoulSelected",1)
		REVO A 0 A_Takeinventory("FlameCannonSelected",1)
		REVO A 0 A_Takeinventory("HasBarrel",1)
		REVO A 0 A_TakeInventory("TossGrenade", 1)
		REVO A 0 A_TakeInventory("Revolver", 1)
		REVO AAAAAA 1 A_Raise

	SelectAnimation:
        TNT1 AAAA 0 A_JumpIfInventory("GoFatality", 1, "Steady")
        REVO LMN 1
		TNT1 A 0 A_PlaySound("REVOHAM", 4)
		REVO OPQR 1
		REVO A 0 A_GunFlash

	Ready3:	
	Ready:	
        REVO A 0 A_JumpIfInventory("Kicking",1,"DoKick")
        REVO A 0 A_JumpIfInventory("Taunting",1,"Taunt")
        REVO A 0 A_JumpIfInventory("Reloading",1,"Reload")
		REVO A 0 A_JumpIfInventory("Salute1", 1, "Salute")
		REVO A 0 A_JumpIfInventory("Salute2", 1, "Salute")
		REVO A 0 A_JumpIfInventory("Unloading",1,"Unload")
		REVO A 0 A_JumpIfInventory("FiredPrimary",1,"Fire")
	OkToFire:
		REVO A 1 A_WeaponReady(WRF_ALLOWRELOAD)
		REVO A 0 A_JumpIfInventory("TossGrenade",1,"TossGrenade")
		REVO A 0 A_JumpIfInventory("IsRunning",1,"CheckSprint")
        Goto Ready
		

	
	Deselect:
		REVO A 0
		REVO A 0 A_Takeinventory("Zoomed",1)
		REVO A 0 A_TakeInventory("TossGrenade", 1)
		REVO A 0 A_Takeinventory("ADSmode",1)
		REVO A 0 A_Takeinventory("UseShotgunStrap",1)
        REVO A 0 A_ZoomFactor(1.0)
		REVO A 1 A_Lower
		Wait

		
    Fire:
        REVO A 0 A_Takeinventory("Reloading",1)
        REVO A 0 A_JumpIfInventory("RevolverAmmo",1,2)
        Goto NoAmmo
        TNT1 AAAA 0
		REVO B 1
		REVO A 0 A_ZoomFactor(0.9)
        REVO A 0 A_AlertMonsters
        REVO A 0 A_PlaySound("REVOFIR", 1)
		RIFF A 0 A_FireCustomMissile("DistantFireSoundShotgun", random(-1,1), 0, 0, -12, 0, random(-1,1))
        REVO A 0 A_SpawnItemEx("PlayerMuzzle1",30,5,30)
		TNT1 AAAAAAAAAAAAAAAA 0 BRIGHT A_FireCustomMissile("ShotgunParticles", random(-12,12), 0, -1, 0, 0, random(-9,9))
		TNT1 AAAAA 0 BRIGHT A_FireCustomMissile("ShotgunParticles2", random(-12,12), 0, -1, 0, 0, random(-9,9))
		TNT1 A 0 A_FireCustomMissile("DecorativeTracer", 0, 0, 0, -12, 0, 0)
		REVO A 0 A_Takeinventory("RevolverAmmo",1)
		REVO A 0 A_FireBullets (1, 1, 1, 100, "ShotgunPuff2", FBF_NORANDOM)
		REVO A 0 A_SetPitch(pitch-10)
		REVO CD 1 BRIGHT
		REVO A 0 A_SetPitch(-6.0 + pitch)
		REVO A 0 A_ZoomFactor(1.00)
		REVO E 1 A_SetPitch(+1.0 + pitch)
		REVO FG 1 A_SetPitch(+1.0 + pitch)
		REVO H 1 A_SetPitch(+1.0 + pitch)
		REVO IJK 1 A_SetPitch(pitch+1.0)
		REVO K 4
		REVO LMN 1
		TNT1 A 0 A_PlaySound("REVOHAM", 4)
		REVO OPQR 1
		Goto Ready3
		
  
	CheckSprint:
		REVO A 1 A_WeaponReady(WRF_NOFIRE)
		REVO A 0 A_Takeinventory("Zoomed",1)
        REVO A 0 A_ZoomFactor(1.0)
		REVO A 0 A_Takeinventory("ADSmode",1)
		REVO A 0 A_Giveinventory("GoSpecial",1)
		REVO A 0 A_JumpIfInventory("IsStandingStill", 1, "Ready3")
		REVO A 0 A_JumpIfInventory("IsTacticalClass", 1, "StartSprint")
		Goto Ready
		
	StartSprint:
		REVO A 1 A_WeaponReady(WRF_NOFIRE)
		REVO A 0 A_Takeinventory("Zoomed",1)
		REVO A 0 A_Takeinventory("ADSmode",1)
		REVO A 0 A_ZoomFactor(1.0)
		REVO A 0 A_JumpIfInventory("UsedStamina", 40, "StopSprintTired")
		
	Sprinting:	
		REVP B 0 offset(-9,32) 
		REVO A 0 offset(-9,32) A_JumpIfInventory("IsStandingStill", 1, "Ready3")
		REVO A 0 offset(-9,32) A_JumpIfInventory("UsedStamina", 100, "StopSprintTired")
		PLAY A 0 offset(-9,32) ACS_ExecuteAlways(852, 0, 0, 0, 0)//Makes player faster.
		REVO A 0 offset(-9,32) A_JumpIfInventory("PowerStrength", 1, 2)
		REVO A 0 offset(-9,32) A_GiveInventory("UsedStamina", 3)
		REVO A 0 offset(-9,32)
		REVP B 1 offset(-9,34) A_SetPitch(pitch -0.5)
		REVP B 1 offset(-6,36) A_SetPitch(pitch -0.5)
		REVP B 1 offset(-3,38) A_SetPitch(pitch -0.5)
		REVP B 1 offset(0,38) A_SetPitch(pitch -0.5)
		REVP B 1 offset(3,36) A_SetPitch(pitch -0.5)
		REVP B 1 offset(6,34) A_SetPitch(pitch -0.5)
		REVP B 1 offset(9,32) A_SetPitch(pitch -0.5)
		REVO A 0 offset(9,32) A_WeaponReady(WRF_NOBOB)
		REVO A 0 A_JumpIfInventory("Kicking",1,"DoKick")
        REVO A 0 A_JumpIfInventory("Taunting",1,"Taunt")
        REVO A 0 A_JumpIfInventory("Reloading",1,"Reload")
		REVO A 0 offset(-9,32) A_GiveInventory("UsedStamina", 3)
		REVO A 0 offset(9,33) A_SpawnItemEx("FootStep", 0, 0, 2, 0, 0, -4)
		REVP B 1 offset(9,34) A_SetPitch(pitch +0.5)
		REVP B 1 offset(6,36) A_SetPitch(pitch +0.5)
		REVP B 1 offset(3,38) A_SetPitch(pitch +0.5)
		REVP B 1 offset(0,38) A_SetPitch(pitch +0.5)
		REVP B 1 offset(-3,36) A_SetPitch(pitch +0.5)
		REVP B 1 offset(-6,34) A_SetPitch(pitch +0.5)
		REVP B 1 offset(-9,32) A_SetPitch(pitch +0.5)
		REVO A 0 offset(-9,32) A_WeaponReady(WRF_NOBOB)
		REVO A 0 offset(-9,32) A_JumpIfInventory("IsRunning", 1, "Sprinting")
		
		Goto StopSprint
	StopSprintTired:
		REVO A 1
		PLAY A 0 ACS_ExecuteAlways(853, 0, 0, 0, 0)//Makes player slower.
		REVO A 0 A_PlaySound("Tired", 2)
		REVO A 0 A_TakeInventory("UsedStamina", 2)
		REVO A 5 A_WeaponReady
		REVO A 0 A_TakeInventory("UsedStamina", 2)
		REVO A 5 A_WeaponReady
		REVO A 0 A_TakeInventory("UsedStamina", 2)
		REVO A 5 A_WeaponReady
		REVO A 0 A_TakeInventory("UsedStamina", 2)
		REVO A 5 A_WeaponReady
		REVO A 0 A_TakeInventory("UsedStamina", 2)
		REVO A 5 A_WeaponReady
		Goto Ready
	StopSprint:
		REVP B 1
		REVO A 0 A_JumpIfInventory("UsedStamina", 60, "StopSprintTired")
		PLAY A 0 ACS_ExecuteAlways(853, 0, 0, 0, 0)//Makes player slower.
		Goto Ready
	
	
    ReloadWithNoAmmoLeft:
    Reload:
	    REVO A 0
		REVO A 0 A_TakeInventory("Reloading", 1)
		REVO A 0 A_JumpIfInventory("Clip2", 1, 2)
		Goto NoAmmo
		REVO A 0
	    REVO A 0 A_Takeinventory("Zoomed",1)
        REVO A 0 A_ZoomFactor(1.0)
		REVO A 1 A_WeaponReady
		REVO A 0 A_JumpIfInventory("RevolverAmmo",6,"OkToFire")
		REVO A 0 A_JumpIfInventory("RevolverAmmo", 1, "ReloadNormally")//Check if there is a shell in the chamber
	
	ReloadNormally:	
        REVO A 0 A_JumpIfInventory("Clip2",1,1)//If there is no reserve ammo, don't reload, go back to Ready
        Goto Ready
		REVO A 0 A_JumpIfInventory("TurboReload", 1, "TurboReload")//Check if reloads are disabled.
		REVR B 0 A_GiveInventory ("Pumping", 1)
		REVR ABCDEEDCBA 1
		TNT1 A 0 A_PLaySound("RELO1", 4)
        REVR FGHIJJJ 1
		REVR KLM 1
		REVR M 4
	 InsertingShells:
		REVO A 0
		REVO A 0 A_JumpIfInventory("Clip2",1,2)//if there are no more reserve shells, finish reload.
        Goto FinishedInsertingShells
		REVO A 0
		REVO A 0 A_GiveInventory ("Pumping", 1)
		SSHR A 0 A_TakeInventory("Reloading", 1)
		TNT1 A 0 A_FireCustomMissile("RifleCAseSpawn",0,0,-10, -20)
        REVO A 0 A_JumpIfInventory("RevolverAmmo",6,"FinishedInsertingShells")
        REVO A 0 A_Giveinventory("RevolverAmmo",1)
		REVO A 0 A_Takeinventory("Clip2",1)
        
	InsertShellAnimation:	
		REVO A 0
        TNT1 A 0 A_PlaySound("insertshell")
		REVR M 1 Offset(0, 30)
		REVR M 1 Offset(0, 28)
		REVR M 1 Offset(0, 30)
		REVR M 1 Offset(0, 32)
        REVR M 4 A_WeaponReady(WRF_NOBOB)
        SSHR A 0 A_JumpIfInventory("Reloading", 1, "FinishedInsertingShells")
        REVO A 0 A_JumpIfInventory("Kicking",1,"DoKickReloading")
		REVO A 0 A_JumpIfInventory("IsRunning",1,"CheckSprint")
		REVO A 0 A_JumpIfInventory("RevolverAmmo",6,"FinishedInsertingShells")//If there are 8+1 shells, stop it immediately
        Goto InsertingShells
	
		
	FinishedInsertingShells:
		REVO A 0 A_Takeinventory("Reloading",1)
		TNT1 A 0 A_PLaySound("RELO2", 4)
		REVR JIHGFAEDCBA 1
		REVO K 4
		REVO LMN 1
		TNT1 A 0 A_PlaySound("REVOHAM", 4)
		REVO OPQR 1
		REVO A 0 A_Takeinventory("Reloading",1)
		Goto Ready
		
	
	 TurboReload:
		SHSS BC 0
	TurboBullets:	
		REVO A 0
		REVO A 0 A_JumpIfInventory("RevolverAmmo",6,"FinishTurboReload")
        REVO A 0 A_JumpIfInventory("Clip2",1,3)
        Goto FinishTurboReload
        TNT1 AAAA 0
        REVO A 0 A_Giveinventory("RevolverAmmo",1)
		REVO A 0 A_Takeinventory("Clip2",1)
		Goto TurboBullets
	FinishTurboReload:
		REVO A 1 A_Refire
		Goto Ready3

      PuristGun:
		TNT1 A 1
		REVO A 0 A_GiveInventory("ClassicShotgun", 1)
		REVO A 0 A_TakeInventory("Shot_Gun", 1)
		TNT1 A 10
		Goto Ready3
		
	AltFire:
		TNT1 A 0
		TNT1 A 0 A_GiveInventory("RevolverChangeAmmo", 1)
		
	Unload:
		REVO A 1
		REVO A 0 A_ZoomFactor(1.0)
		REVO A 0 A_Takeinventory("Unloading",1)
		REVO A 0 A_Takeinventory("ADSmode",1)
		REVO A 0 A_Takeinventory("Zoomed",1)
        REVO A 0 A_JumpIfInventory("RevolverAmmo",1,3)
        Goto OkToFire
        TNT1 AAA 0
		REVO A 0 A_Takeinventory("Zoomed",1)
		REVO A 0 A_GiveInventory ("Pumping", 1)
		REVO A 0 A_Takeinventory("Unloading",1)
		REVR ABCDEEDCBA 1
		TNT1 A 0 A_PLaySound("RELO1", 4)
        REVR FGHIJJJ 1
		REVR KLM 1
		REVR M 4
		
	RemoveBullets:
		TNT1 AAAA 0
		REVO A 0 A_JumpIfInventory("RevolverAmmo",1,3)
		Goto FinishUnload
        TNT1 AAAAAA 0
		REVO A 0 A_Takeinventory("RevolverAmmo",1)
		REVO A 0 A_Giveinventory("Clip2",1)
		
		REVR M 1 Offset(0, 30)
		REVR M 1 Offset(0, 28)
		REVR M 1 Offset(0, 30)
		REVR M 1 Offset(0, 32)
		Goto RemoveBullets

	FInishUnload:
		TNT1 A 0 
		TNT1 A 0 A_JumpIfInventory("RevolverChangeAmmo", 1, "ChangeAmmo")
		REVO A 0 A_Takeinventory("Unloading",1)
		Goto OkToFire	
		
	ChangeAmmo:
		TNT1 A 0
		TNT1 A 0 A_TakeInventory("RevolverChangeAmmo", 1)
		TNT1 A 0 A_GiveInventory("Revolver")
		TNT1 A 0 A_GiveInventory("Reloading", 1)
		TNT1 A 0 A_SelectWeapon("Revolver")
		Goto Ready	
		
		
	DoKickReloading:
		NULL A 0 A_JumpIf (momZ > 0, "AirKick")
		NULL A 0 A_JumpIf (momZ < 0, "AirKick")
        REVO A 0 A_PlaySound("KICK")
		REVO A 0 SetPlayerProperty(0,1,0)
		KICK BCD 1
		RIFF A 0 A_FireCustomMissile("KickAttack", 0, 0, 0, -7)
        KICK H 3
		KICK A 0 A_Takeinventory("Kicking",1)
		KICK I 1
		KICK GFEDCBA 1 
		RIBA A 0 A_Takeinventory("Kicking",1)
		REVO A 0 SetPlayerProperty(0,0,0)
		Goto InsertingShells
		
	Steady:
		TNT1 A 1
		Goto Ready
		
		

	NoAmmo:
		RIFG A 0
		RIFG A 0 A_ZoomFactor(1.0)
		RIFG A 0 A_Takeinventory("Zoomed",1)
		RIFG A 0 A_Takeinventory("ADSmode",1)
		RIFG A 0 A_JumpIfInventory("TurboReload",1,"TurboReload")
		TNT1 A 0 A_PlaySound("weapons/empty", 4)
		NoAmmo2:
		RIFG A 0 A_JumpIfInventory("TossGrenade",1,"TossGrenade")
	    RIFG A 0 A_JumpIfInventory("Taunting",1,"Taunt")
		RIFG A 0 A_JumpIfInventory("Salute1", 1, "Salute")
		RIFG A 0 A_JumpIfInventory("Salute2", 1, "Salute")
		RIFG A 0 A_JumpIfInventory("IsRunning",1,"CheckSprint")
		RIFG A 0 A_JumpIfInventory("ExecuteDownedEnemy", 1, "DoExecution")
		RIFG A 0 A_JumpIfInventory("Kicking",1,"DoKick")
		REVO A 5 A_WeaponReady(WRF_ALLOWRELOAD | WRF_NOFIRE)
		RIFG A 0 A_JumpIfInventory("Reloading",1,"Reload")
		RIFG A 0 A_JumpIfInventory("TurboReload",1,"TurboReload")
		TNT1 A 0 A_JumpIfInventory("NoAutoReload", 1, "NoAmmo2")
		RIFG A 0 A_JumpIfInventory("Clip2",1,"Reload")
		RIFG A 0 A_JumpIfInventory("FiredPrimary",1,"NoAmmo2")
		Goto Ready3
			
	}
}


